barebones flake.nix

README.md

@@ -51,6 +51,29 @@ If you want to try out the newest unstable features, you may install the CLI fro
 cargo install --git https://github.com/TheBevyFlock/bevy_cli --branch main --locked bevy_cli
 ```
 
+### Nix
+
+> Please note that Nix support is maintained on a best-effort basis, and therefore should not be considered stable. Features may be unavailable or break altogether as a result of future changes.
+
+The CLI and Linter are also available to Nix users as a [flake](https://wiki.nixos.org/wiki/Flakes). Simply add it as an input to your project's `flake.nix` to include it in the environment:
+
+```nix
+{
+  description = "A Bevy project flake.";
+
+  inputs = {
+    # Other inputs...
+    bevy_cli.url = "github:TheBevyFlock/bevy_cli";
+  };
+
+  outputs = { self, bevy_cli }: {
+    # Your outputs...
+  };
+}
+```
+
+An [example](https://github.com/bevyengine/bevy/blob/2facb2572d84e9b9923edef7f35bae2c26308081/docs/linux_dependencies.md#flakenix) project flake can be found in the official Bevy docs.
+
 ## Quick Start
 
 <!-- Please keep this section synchronized with the `mdbook` docs. -->

flake.nix

@@ -0,0 +1,61 @@
+{
+  description = "A Bevy CLI tool and linter";
+
+  inputs = {
+    flake-utils.url = "github:numtide/flake-utils";
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
+    rust-overlay = {
+      url = "github:oxalica/rust-overlay";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs = { self, flake-utils, nixpkgs, rust-overlay }:
+    flake-utils.lib.eachDefaultSystem (
+      system:
+      let
+        pkgs = nixpkgs.legacyPackages.${system}.extend rust-overlay.overlays.default;
+
+        nativeBuildInputs = with pkgs; [
+          pkg-config
+        ];
+
+        buildInputs = with pkgs; [
+          openssl
+        ];
+
+        toolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
+
+        rustPlatform = pkgs.makeRustPlatform {
+          cargo = toolchain;
+          rustc = toolchain;
+        };
+      in
+      {
+        packages = {
+          default = self.outputs.packages.${system}.bevy;
+          bevy = rustPlatform.buildRustPackage {
+            pname = "bevy";
+            version = "0.1.0-dev";
+            src = ./.;
+            cargoLock.lockFile = ./Cargo.lock;
+            cargoBuildFlags = [ "--all" ];
+            doCheck = false;
+
+            nativeBuildInputs = nativeBuildInputs ++ (with pkgs; [ makeBinaryWrapper ]);
+            inherit buildInputs;
+
+            postInstall = ''
+              for bin in $out/bin/bevy{,_lint}; do
+                wrapProgram $bin --set BEVY_LINT_SYSROOT ${toolchain}
+              done
+            '';
+          };
+        };
+
+        devShells.default = pkgs.mkShell {
+          inherit buildInputs nativeBuildInputs;
+        };
+      }
+    );
+}