Add BigInt Support to Objective-C Turbo Module (#56020)

Summary:
Pull Request resolved: #56020

This diff adds BigInt method support to the Objective-C sample Turbo Module,
demonstrating how to use 64-bit integers with BigInt bridging on iOS.

Changes:
- Added getBigInt method declaration in RCTNativeSampleTurboModuleSpec.h
  using C++ int64_t type
- Added host function binding in RCTNativeSampleTurboModuleSpec.mm using BigIntKind
- Implemented getBigInt in RCTSampleTurboModule.mm using
  RCT_EXPORT_SYNCHRONOUS_TYPED_METHOD
- Fixed BigInt rendering in NativeCxxModuleExampleExample.js and
  SampleTurboModuleExample.js — JSON.stringify() cannot serialize BigInt,
  so bigint values are now rendered via .toString()

The ObjC bridge maps getBigInt to an NSNumber* return with BigIntKind, which
instructs the TurboModule infrastructure to convert via
jsi::BigInt::fromInt64().

## Conversion Table
| NSNumber Method | Underlying Type | Min | Max |
| --- | --- | --- | --- |
| numberWithChar: | char | -128 | 127 |
| numberWithShort: | short | -32,768 | 32,767 |
| numberWithInt: | int | -2,147,483,648 | 2,147,483,647 |
| numberWithLongLong: | long long | -9,223,372,036,854,775,808 | 9,223,372,036,854,775,807 |
| numberWithUnsignedLongLong: | unsigned long long | 0 | 18,446,744,073,709,551,615 |

Changelog: [iOS][Added] - Add BigInt Support to Objective-C Turbo Module

Differential Revision: D95232266

Author: christophpurrer

packages/react-native/ReactCommon/react/nativemodule/core/platform/ios/ReactCommon/RCTTurboModule.mm

@@ -25,6 +25,7 @@
 #import <objc/message.h>
 #import <objc/runtime.h>
 #import <atomic>
+#import <cstring>
 #import <iostream>
 #import <mutex>
 
@@ -188,6 +189,16 @@ id convertJSIValueToObjCObject(
   if (value.isString()) {
     return convertJSIStringToNSString(runtime, value.getString(runtime));
   }
+  if (value.isBigInt()) {
+    auto bigint = value.getBigInt(runtime);
+    if (bigint.isInt64(runtime)) {
+      return [NSNumber numberWithLongLong:bigint.getInt64(runtime)];
+    }
+    if (bigint.isUint64(runtime)) {
+      return [NSNumber numberWithUnsignedLongLong:bigint.getUint64(runtime)];
+    }
+    throw jsi::JSError(runtime, "BigInt value is too large for int64_t or uint64_t");
+  }
   if (value.isObject()) {
     jsi::Object o = value.getObject(runtime);
     if (o.isArray(runtime)) {
@@ -526,7 +537,14 @@ TraceSection s(
     case PromiseKind:
       throw jsi::JSError(runtime, "convertReturnIdToJSIValue: PromiseKind wasn't handled properly.");
     case BigIntKind: {
-      returnValue = jsi::BigInt::fromInt64(runtime, [(NSNumber *)result longLongValue]);
+      auto num = (NSNumber *)result;
+      const char *type = [num objCType];
+      if (type != nullptr &&
+          (strcmp(type, @encode(unsigned long long)) == 0 || strcmp(type, @encode(unsigned long)) == 0)) {
+        returnValue = jsi::BigInt::fromUint64(runtime, [num unsignedLongLongValue]);
+      } else {
+        returnValue = jsi::BigInt::fromInt64(runtime, [num longLongValue]);
+      }
       break;
     }
   }
@@ -630,9 +648,40 @@ TraceSection s(
       [retainedObjectsForInvocation addObject:objCArg];
     } else if (objCArgType == @encode(NSInteger)) {
       NSInteger integer = v;
-      [inv setArgument:&integer atIndex:i + 2];
+      [inv setArgument:&integer atIndex:static_cast<NSInteger>(i + 2)];
     } else {
-      [inv setArgument:(void *)&v atIndex:i + 2];
+      [inv setArgument:(void *)&v atIndex:static_cast<NSInteger>(i + 2)];
+    }
+
+    return;
+  }
+
+  if (arg.isBigInt()) {
+    auto bigint = arg.getBigInt(runtime);
+
+    /**
+     * JS type checking ensures the Objective C argument here is either a long long or NSNumber*.
+     */
+    if (bigint.isInt64(runtime)) {
+      int64_t v = bigint.getInt64(runtime);
+      if (objCArgType == @encode(id)) {
+        id objCArg = [NSNumber numberWithLongLong:v];
+        [inv setArgument:(void *)&objCArg atIndex:static_cast<NSInteger>(i + 2)];
+        [retainedObjectsForInvocation addObject:objCArg];
+      } else {
+        [inv setArgument:(void *)&v atIndex:static_cast<NSInteger>(i + 2)];
+      }
+    } else if (bigint.isUint64(runtime)) {
+      uint64_t v = bigint.getUint64(runtime);
+      if (objCArgType == @encode(id)) {
+        id objCArg = [NSNumber numberWithUnsignedLongLong:v];
+        [inv setArgument:(void *)&objCArg atIndex:static_cast<NSInteger>(i + 2)];
+        [retainedObjectsForInvocation addObject:objCArg];
+      } else {
+        [inv setArgument:(void *)&v atIndex:static_cast<NSInteger>(i + 2)];
+      }
+    } else {
+      throw jsi::JSError(runtime, "BigInt value is too large for int64_t or uint64_t");
     }
 
     return;

packages/react-native/ReactCommon/react/nativemodule/samples/platform/ios/ReactCommon/RCTNativeSampleTurboModuleSpec.h

@@ -7,6 +7,7 @@
 
 // NOTE: This entire file should be codegen'ed.
 
+#import <cstdint>
 #import <vector>
 
 #ifndef __cplusplus
@@ -104,6 +105,7 @@ inline JS::NativeSampleTurboModule::Constants::Builder::Builder(Constants i)
 - (NSDictionary *)getObjectAssert:(NSDictionary *)arg;
 - (void)promiseAssert:(RCTPromiseResolveBlock)resolve reject:(RCTPromiseRejectBlock)reject;
 - (void)getImageUrl:(RCTPromiseResolveBlock)resolve reject:(RCTPromiseRejectBlock)reject;
+- (NSNumber *)getBigInt:(int64_t)arg;
 - (facebook::react::ModuleConstants<JS::NativeSampleTurboModule::Constants>)constantsToExport;
 - (facebook::react::ModuleConstants<JS::NativeSampleTurboModule::Constants>)getConstants;
 

packages/react-native/ReactCommon/react/nativemodule/samples/platform/ios/ReactCommon/RCTNativeSampleTurboModuleSpec.mm

@@ -214,6 +214,16 @@ - (void)setEventEmitterCallback:(EventEmitterCallbackWrapper *)eventEmitterCallb
       .invokeObjCMethod(rt, PromiseKind, "promiseAssert", @selector(promiseAssert:reject:), args, count);
 }
 
+static facebook::jsi::Value __hostFunction_NativeSampleTurboModuleSpecJSI_getBigInt(
+    facebook::jsi::Runtime &rt,
+    TurboModule &turboModule,
+    const facebook::jsi::Value *args,
+    size_t count)
+{
+  return static_cast<ObjCTurboModule &>(turboModule)
+      .invokeObjCMethod(rt, BigIntKind, "getBigInt", @selector(getBigInt:), args, count);
+}
+
 static facebook::jsi::Value __hostFunction_NativeSampleTurboModuleSpecJSI_getImageUrl(
     facebook::jsi::Runtime &rt,
     TurboModule &turboModule,
@@ -275,6 +285,9 @@ - (void)setEventEmitterCallback:(EventEmitterCallbackWrapper *)eventEmitterCallb
 
   methodMap_["promiseAssert"] = MethodMetadata{0, __hostFunction_NativeSampleTurboModuleSpecJSI_promiseAssert};
 
+  methodMap_["getBigInt"] =
+      MethodMetadata{.argCount = 1, .invoker = __hostFunction_NativeSampleTurboModuleSpecJSI_getBigInt};
+
   methodMap_["getImageUrl"] = MethodMetadata{0, __hostFunction_NativeSampleTurboModuleSpecJSI_getImageUrl};
 
   methodMap_["getConstants"] = MethodMetadata{0, __hostFunction_NativeSampleTurboModuleSpecJSI_getConstants};

packages/react-native/ReactCommon/react/nativemodule/samples/platform/ios/ReactCommon/RCTSampleTurboModule.mm

@@ -210,6 +210,11 @@ - (void)installJSIBindingsWithRuntime:(facebook::jsi::Runtime &)runtime
   RCTAssert(false, @"Intentional assert from ObjC promiseAssert");
 }
 
+RCT_EXPORT_SYNCHRONOUS_TYPED_METHOD(NSNumber *, getBigInt : (int64_t)arg)
+{
+  return @(arg);
+}
+
 @end
 
 Class _Nonnull RCTSampleTurboModuleCls(void)