ipod_theme/05_optional_strings_pack.bat at master · nfzerox/ipod_theme · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
@echo off
setlocal enabledelayedexpansion

cd /d "%~dp0"

REM Create list of language folders
set /a count=0
for /d %%L in ("Languages\SilverDB.*.LE") do (
    set /a count+=1
    set "lang[!count!]=%%~nxL"
)

REM Display menu
echo Select languages for packaging:
for /L %%i in (1,1,!count!) do (
    echo   %%i^) !lang[%%i]!
)

set /a all_index=!count! + 1
echo   !all_index!^) All languages

REM Get user input
set /p selection="Enter numbers separated by spaces: "

REM Check if "all" selected
echo %selection% | findstr /C:"!all_index!" >nul
if not errorlevel 1 (
    echo Packaging all languages...
    for /L %%i in (1,1,!count!) do (
        echo Packaging !lang[%%i]!...
        "silverutil\target\release\silverutil.exe" create "Languages\!lang[%%i]!" "Languages\!lang[%%i]!.bin2"
    )
    pause
    exit /b 0
)

REM Process individual selections
for %%n in (%selection%) do (
    if %%n LEQ !count! if %%n GEQ 1 (
        echo Packaging !lang[%%n]!...
        "silverutil\target\release\silverutil.exe" create "Languages\!lang[%%n]!" "Languages\!lang[%%n]!.bin2"
    )
)
pause