Add shfmt.

Author: infokiller

README.md

@@ -24,6 +24,7 @@ helpfiles in the `doc/` directory. The helpfiles are also available via
 * Proto (clang-format)
 * Python (Autopep8 or YAPF)
 * TypeScript (clang-format)
+* Shell (shfmt)
 
 # Commands
 

autoload/codefmt/shfmt.vim

@@ -0,0 +1,91 @@
+" Copyright 2017 Google Inc. All rights reserved.
+"
+" Licensed under the Apache License, Version 2.0 (the "License");
+" you may not use this file except in compliance with the License.
+" You may obtain a copy of the License at
+"
+"     http://www.apache.org/licenses/LICENSE-2.0
+"
+" Unless required by applicable law or agreed to in writing, software
+" distributed under the License is distributed on an "AS IS" BASIS,
+" WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+" See the License for the specific language governing permissions and
+" limitations under the License.
+
+
+let s:plugin = maktaba#plugin#Get('codefmt')
+
+
+""
+" @private
+" Formatter: shfmt
+function! codefmt#shfmt#GetFormatter() abort
+  let l:formatter = {
+      \ 'name': 'shfmt',
+      \ 'setup_instructions': 'Install shfmt and configure the ' .  
+          \ 'shfmt_executable flag'}
+
+  function l:formatter.IsAvailable() abort
+    return executable(s:plugin.Flag('shfmt_executable'))
+  endfunction
+
+  function l:formatter.AppliesToBuffer() abort
+    return &filetype is# 'sh'
+  endfunction
+
+  ""
+  " Reformat the current buffer with shfmt or the binary named in
+  " @flag(shfmt_executable), only targeting the range between {startline} and
+  " {endline}.
+  function l:formatter.FormatRange(startline, endline) abort
+    let l:Shfmt_options = s:plugin.Flag('shfmt_options')
+    if type(l:Shfmt_options) is# type([])
+      let l:shfmt_options = l:Shfmt_options
+    elseif maktaba#value#IsCallable(l:Shfmt_options)
+      let l:shfmt_options = maktaba#function#Call(l:Shfmt_options)
+    else
+      throw maktaba#error#WrongType(
+          \ 'shfmt_options flag must be list or callable. Found %s',
+          \ string(l:Shfmt_options))
+    endif
+    " Hack range formatting by formatting range individually, ignoring context.
+    let l:cmd = [ s:plugin.Flag('shfmt_executable') ] + l:shfmt_options
+    call maktaba#ensure#IsNumber(a:startline)
+    call maktaba#ensure#IsNumber(a:endline)
+    let l:lines = getline(1, line('$'))
+    let l:input = join(l:lines[a:startline - 1 : a:endline - 1], "\n")
+    try
+      let l:result = maktaba#syscall#Create(l:cmd).WithStdin(l:input).Call()
+      let l:formatted = split(l:result.stdout, "\n")
+      " Special case empty slice: neither l:lines[:0] nor l:lines[:-1] is right.
+      let l:before = a:startline > 1 ? l:lines[ : a:startline - 2] : []
+
+      let l:full_formatted = l:before + l:formatted + l:lines[a:endline :]
+      call maktaba#buffer#Overwrite(1, line('$'), l:full_formatted)
+    catch /ERROR(ShellError):/
+      " Parse all the errors and stick them in the quickfix list.
+      let l:errors = []
+      for l:line in split(v:exception, "\n")
+        let l:tokens = matchlist(l:line,
+            \ '\C\v^\<standard input\>:(\d+):(\d+):\s*(.*)')
+        if !empty(l:tokens)
+          call add(l:errors, {
+              \ 'filename': @%,
+              \ 'lnum': l:tokens[1] + a:startline - 1,
+              \ 'col': l:tokens[2],
+              \ 'text': l:tokens[3]})
+        endif
+      endfor
+
+      if empty(l:errors)
+        " Couldn't parse shfmt error format; display it all.
+        call maktaba#error#Shout('Error formatting file: %s', v:exception)
+      else
+        call setqflist(l:errors, 'r')
+        cc 1
+      endif
+    endtry
+  endfunction
+
+  return l:formatter
+endfunction

instant/flags.vim

@@ -93,3 +93,14 @@ call s:plugin.Flag('buildifier_executable', 'buildifier')
 " form:
 " `java -jar /path/to/google-java`
 call s:plugin.Flag('google_java_executable', 'google-java-format')
+
+""
+" Command line arguments to to feed shfmt. Either a list or callable that
+" takes no args and returns a list with command line arguments. By default, uses
+" the Google's style.
+" See https://github.com/mvdan/sh for details.
+call s:plugin.Flag('shfmt_options', ['-i', '2', '-sr', '-ci'])
+
+""
+" The path to the shfmt executable.
+call s:plugin.Flag('shfmt_executable', 'shfmt')

plugin/register.vim

@@ -30,3 +30,4 @@ call s:registry.AddExtension(codefmt#autopep8#GetFormatter())
 call s:registry.AddExtension(codefmt#gn#GetFormatter())
 call s:registry.AddExtension(codefmt#buildifier#GetFormatter())
 call s:registry.AddExtension(codefmt#googlejava#GetFormatter())
+call s:registry.AddExtension(codefmt#shfmt#GetFormatter())

vroom/shfmt.vroom

@@ -0,0 +1,84 @@
+The built-in shfmt formatter knows how to format shell code (POSIX/Bash/mksh).
+If you aren't familiar with basic codefmt usage yet, see main.vroom first.
+
+We'll set up codefmt and configure the vroom environment, then jump into some
+examples.
+
+  :source $VROOMDIR/setupvroom.vim
+
+  :let g:repeat_calls = []
+  :function FakeRepeat(...)<CR>
+  |  call add(g:repeat_calls, a:000)<CR>
+  :endfunction
+  :call maktaba#test#Override('repeat#set', 'FakeRepeat')
+
+  :call codefmt#SetWhetherToPerformIsAvailableChecksForTesting(0)
+
+
+The shfmt formatter expects the shfmt executable to be installed on your system.
+
+  % f()
+  :FormatCode shfmt
+  ! shfmt .*
+  $ f()
+
+The name or path of the shfmt executable can be configured via the
+shfmt_executable flag if the default of "shfmt" doesn't work.
+
+  :Glaive codefmt shfmt_executable='myshfmt'
+  :FormatCode shfmt
+  ! myshfmt .*
+  $ f()
+  :Glaive codefmt shfmt_executable='shfmt'
+
+
+You can format any buffer with shfmt specifying the formatter explicitly.
+
+  @clear
+  % if [  $print_hello_world -eq  1  ]; then echo "hello"; echo "world"; fi
+
+  :FormatCode shfmt
+  ! shfmt .*2>.*
+  $ if [ $print_hello_world -eq 1 ]; then
+  $   echo "hello"
+  $   echo "world"
+  $ fi
+  if [ $print_hello_world -eq 1 ]; then
+    echo "hello"
+    echo "world"
+  fi
+  @end
+
+The sh filetype will use the shfmt formatter by default.
+
+  @clear
+  % f()
+
+  :set filetype=sh
+  :FormatCode
+  ! shfmt .*
+  $ f()
+
+  :set filetype=
+
+It can format specific line ranges of code using :FormatLines.
+
+  @clear
+  % foo() { echo "my name is:"; echo "foo"; }<CR>
+  |bar() { echo "my name is:"; echo "bar"; }
+
+  :1,2FormatLines shfmt
+  ! shfmt .*2>.*
+  $ foo() {
+  $   echo "my name is:"
+  $   echo "foo"
+  $ }
+  foo() {
+    echo "my name is:"
+    echo "foo"
+  }
+  bar() { echo "my name is:"; echo "bar"; }
+  @end
+
+NOTE: the shfmt formatter does not natively support range formatting, so there
+are certain limitations like not being able to format misaligned braces.