JS: Factor out tsconfig path mapping support

Author: asgerf

javascript/ql/lib/semmle/javascript/internal/paths/PathExprResolver.qll

@@ -1,7 +1,7 @@
 private import javascript
-private import semmle.javascript.TSConfig
 private import semmle.javascript.internal.paths.PackageJsonEx
 private import semmle.javascript.internal.paths.JSPaths
+private import semmle.javascript.internal.paths.PathMapping
 private import semmle.javascript.internal.paths.PathConcatenation
 private import semmle.javascript.dataflow.internal.DataFlowNode
 
@@ -81,28 +81,11 @@ module ResolveExpr<exprSig/1 shouldResolveExpr> {
   }
 
   /**
-   * Gets a tsconfig file to use as fallback for handling paths in `c`.
-   *
-   * This holds for files and folders where no tsconfig seems to include it,
-   * but it has one or more tsconfig files in parent directories.
-   */
-  private TSConfig getFallbackTSConfig(Container c) {
-    not c = any(TSConfig t).getAnIncludedContainer() and
-    (
-      c = result.getFolder()
-      or
-      result = getFallbackTSConfig(c.getParentContainer())
-    )
-  }
-
-  /**
-   * Gets the TSConfig file relevant for resolving `expr`.
+   * Gets a path mapping relevant for resolving `expr`.
    */
   pragma[nomagic]
-  private TSConfig getTSConfigFromPathExpr(RelevantExpr expr) {
-    result.getAnIncludedContainer() = expr.getFile()
-    or
-    result = getFallbackTSConfig(expr.getFile())
+  private PathMapping getAPathMappingFromPathExpr(RelevantExpr expr) {
+    result.getAnAffectedFile() = expr.getFile()
   }
 
   /**
@@ -126,23 +109,23 @@ module ResolveExpr<exprSig/1 shouldResolveExpr> {
    */
   pragma[nomagic]
   private predicate resolveViaPathMapping(RelevantExpr expr, Container base, string newPath) {
-    // Handle tsconfig mappings such as `{ "paths": { "@/*": "./src/*" }}`
-    exists(TSConfig config, string value |
-      config = getTSConfigFromPathExpr(expr).getExtendedTSConfig*() and
-      value = expr.getValue() and
-      base = config.getBaseUrlFolderOrOwnFolder()
+    // Handle path mappings such as `{ "paths": { "@/*": "./src/*" }}` in a tsconfig.json file
+    exists(PathMapping mapping, string value |
+      mapping = getAPathMappingFromPathExpr(expr) and
+      value = expr.getValue()
     |
-      config.hasExactPathMapping(value, newPath)
+      mapping.hasExactPathMapping(value, base, newPath)
       or
       exists(string pattern, string suffix, string mappedPath |
-        config.hasPrefixPathMapping(pattern, mappedPath) and
+        mapping.hasPrefixPathMapping(pattern, base, mappedPath) and
         value = pattern + suffix and
         newPath = mappedPath + suffix
       )
     )
     or
     // Handle imports referring to a package by name, where we have a package.json
-    // file for that package in the codebase.
+    // file for that package in the codebase. This is treated separately from PathMapping for performance
+    // reasons, as there can be a large number of packages which affect all files in the project.
     //
     // This part only handles the "exports" property of package.json. "main" and "modules" are
     // handled further down because their semantics are easier to handle there.
@@ -197,7 +180,7 @@ module ResolveExpr<exprSig/1 shouldResolveExpr> {
     // Resolve from baseUrl of relevant tsconfig.json file
     path = expr.getValue() and
     not isRelativePath(path) and
-    base = getTSConfigFromPathExpr(expr).getBaseUrlFolder()
+    getAPathMappingFromPathExpr(expr).hasBaseUrl(base)
     or
     // If the path starts with the name of a package, but did not match any path mapping,
     // resolve relative to the enclosing directory of that package.
@@ -242,10 +225,6 @@ module ResolveExpr<exprSig/1 shouldResolveExpr> {
 
     query PathExprToDebug pathExprs() { any() }
 
-    query TSConfig getTSConfigFromPathExpr_(PathExprToDebug expr) {
-      result = getTSConfigFromPathExpr(expr)
-    }
-
     query string getPackagePrefixFromPathExpr_(PathExprToDebug expr) {
       result = getPackagePrefixFromPathExpr(expr)
     }

javascript/ql/lib/semmle/javascript/internal/paths/PathMapping.qll

@@ -0,0 +1,72 @@
+/**
+ * Provides an extensible mechanism for modeling path mappings.
+ */
+
+private import javascript
+private import semmle.javascript.TSConfig
+
+/**
+ * A configuration entity, such as a `tsconfig.json` file, which may provide path mappings.
+ */
+abstract class PathMapping extends Locatable {
+  /**
+   * Gets a file affected by this path mapping.
+   */
+  abstract File getAnAffectedFile();
+
+  /**
+   * Holds if imports paths exactly matching `pattern` should be redirected to `newPath`
+   * resolved relative to `newContext`.
+   */
+  abstract predicate hasExactPathMapping(string pattern, Container newContext, string newPath);
+
+  /**
+   * Holds if imports paths starting with `pattern` should have the matched prefix replaced by `newPath`
+   * and then resolved relative to `newContext`.
+   */
+  abstract predicate hasPrefixPathMapping(string pattern, Container newContext, string newPath);
+
+  /** Holds if non-relative paths in affected files should be resolved relative to `base`. */
+  abstract predicate hasBaseUrl(Container base);
+}
+
+/**
+ * Gets a tsconfig file to use as fallback for handling paths in `c`.
+ *
+ * This holds for files and folders where no tsconfig seems to include it,
+ * but it has one or more tsconfig files in parent directories.
+ */
+private TSConfig getFallbackTSConfig(Container c) {
+  not c = any(TSConfig t).getAnIncludedContainer() and
+  (
+    c = result.getFolder()
+    or
+    result = getFallbackTSConfig(c.getParentContainer())
+  )
+}
+
+private class TSConfigPathMapping extends PathMapping, TSConfig {
+  override File getAnAffectedFile() {
+    result = this.getAnIncludedContainer()
+    or
+    this = getFallbackTSConfig(result)
+  }
+
+  override predicate hasExactPathMapping(string pattern, Container newContext, string newPath) {
+    exists(TSConfig tsconfig |
+      tsconfig = this.getExtendedTSConfig*() and
+      tsconfig.hasExactPathMapping(pattern, newPath) and
+      newContext = tsconfig.getBaseUrlFolderOrOwnFolder()
+    )
+  }
+
+  override predicate hasPrefixPathMapping(string pattern, Container newContext, string newPath) {
+    exists(TSConfig tsconfig |
+      tsconfig = this.getExtendedTSConfig*() and
+      tsconfig.hasPrefixPathMapping(pattern, newPath) and
+      newContext = tsconfig.getBaseUrlFolderOrOwnFolder()
+    )
+  }
+
+  override predicate hasBaseUrl(Container base) { base = this.getBaseUrlFolder() }
+}