Use getLocation instead of hasLocationInfo

Author: owen-mc

go/ql/lib/semmle/go/DiagnosticsReporting.qll

@@ -19,20 +19,10 @@ private class Diagnostic extends @diagnostic {
   string getMessage() { diagnostics(this, _, _, result, _, _) }
 
   /** Gets the file that this error is associated with, if any. */
-  File getFile() { this.hasLocationInfo(result.getAbsolutePath(), _, _, _, _) }
+  File getFile() { result = this.getLocation().getFile() }
 
-  /**
-   * Holds if this element is at the specified location.
-   * The location spans column `startcolumn` of line `startline` to
-   * column `endcolumn` of line `endline` in file `filepath`.
-   * For more information, see
-   * [Locations](https://codeql.github.com/docs/writing-codeql-queries/providing-locations-in-codeql-queries/).
-   */
-  predicate hasLocationInfo(string path, int sl, int sc, int el, int ec) {
-    exists(Location loc | diagnostics(this, _, _, _, _, loc) |
-      loc.hasLocationInfo(path, sl, sc, el, ec)
-    )
-  }
+  /** Gets the location for this error. */
+  Location getLocation() { diagnostics(this, _, _, _, _, result) }
 
   string toString() { result = this.getMessage() }
 }
@@ -69,7 +59,7 @@ predicate reportableDiagnostics(Diagnostic d, string msg, int sev) {
     exists(File f | f = d.getFile() |
       exists(f.getAChild()) and
       msg =
-        "Extraction failed in " + d.getFile().getRelativePath() + " with error " +
+        "Extraction failed in " + f.getRelativePath() + " with error " +
           removeAbsolutePaths(d.getMessage())
     )
     or

go/ql/lib/semmle/go/Scopes.qll

@@ -144,36 +144,34 @@ class Entity extends @object {
   /** Gets a textual representation of this entity. */
   string toString() { result = this.getName() }
 
-  private predicate hasRealLocationInfo(
-    string filepath, int startline, int startcolumn, int endline, int endcolumn
-  ) {
-    // take the location of the declaration if there is one
-    this.getDeclaration().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn) or
-    any(CaseClause cc | this = cc.getImplicitlyDeclaredVariable())
-        .hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
+  /** Gets the location of this entity. */
+  Location getLocation() {
+    result = this.getDeclaration().getLocation()
+    or
+    result = any(CaseClause cc | this = cc.getImplicitlyDeclaredVariable()).getLocation()
   }
 
   /**
+   * DEPRECATED: Use `getLocation()` instead.
+   *
    * Holds if this element is at the specified location.
    * The location spans column `startcolumn` of line `startline` to
    * column `endcolumn` of line `endline` in file `filepath`.
    * For more information, see
    * [Locations](https://codeql.github.com/docs/writing-codeql-queries/providing-locations-in-codeql-queries/).
    */
-  predicate hasLocationInfo(
+  deprecated predicate hasLocationInfo(
     string filepath, int startline, int startcolumn, int endline, int endcolumn
   ) {
-    // take the location of the declaration if there is one
-    if this.hasRealLocationInfo(_, _, _, _, _)
-    then this.hasRealLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
-    else (
-      // otherwise fall back on dummy location
-      filepath = "" and
-      startline = 0 and
-      startcolumn = 0 and
-      endline = 0 and
-      endcolumn = 0
-    )
+    this.getLocation().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
+    or
+    // otherwise fall back on dummy location
+    not exists(this.getLocation()) and
+    filepath = "" and
+    startline = 0 and
+    startcolumn = 0 and
+    endline = 0 and
+    endcolumn = 0
   }
 }
 
@@ -680,16 +678,22 @@ class Callable extends TCallable {
     result = this.asFuncLit().getName()
   }
 
+  /** Gets the location of this callable. */
+  Location getLocation() {
+    result = this.asFunction().getLocation() or result = this.asFuncLit().getLocation()
+  }
+
   /**
+   * DEPRECATED: Use `getLocation()` instead.
+   *
    * Holds if this element is at the specified location.
    * The location spans column `sc` of line `sl` to
    * column `ec` of line `el` in file `fp`.
    * For more information, see
    * [Locations](https://codeql.github.com/docs/writing-codeql-queries/providing-locations-in-codeql-queries/).
    */
-  predicate hasLocationInfo(string fp, int sl, int sc, int el, int ec) {
-    this.asFunction().hasLocationInfo(fp, sl, sc, el, ec) or
-    this.asFuncLit().hasLocationInfo(fp, sl, sc, el, ec)
+  deprecated predicate hasLocationInfo(string fp, int sl, int sc, int el, int ec) {
+    this.getLocation().hasLocationInfo(fp, sl, sc, el, ec)
   }
 }
 

go/ql/lib/semmle/go/StringOps.qll

@@ -548,20 +548,25 @@ module StringOps {
         else result = "concatenation element"
     }
 
+    /** Gets the location of this element. */
+    Location getLocation() { result = this.asNode().getLocation() }
+
     /**
+     * DEPRECATED: Use `getLocation()` instead.
+     *
      * Holds if this element is at the specified location.
      * The location spans column `startcolumn` of line `startline` to
      * column `endcolumn` of line `endline` in file `filepath`.
      * For more information, see
      * [Locations](https://codeql.github.com/docs/writing-codeql-queries/providing-locations-in-codeql-queries/).
      */
-    predicate hasLocationInfo(
+    deprecated predicate hasLocationInfo(
       string filepath, int startline, int startcolumn, int endline, int endcolumn
     ) {
-      this.asNode().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
+      this.getLocation().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
       or
       // use dummy location for elements that don't have a corresponding node
-      not exists(this.asNode()) and
+      not exists(this.getLocation()) and
       filepath = "" and
       startline = 0 and
       startcolumn = 0 and

go/ql/lib/semmle/go/Types.qll

@@ -144,19 +144,24 @@ class Type extends @type {
    */
   string toString() { result = this.getName() }
 
+  /** Gets the location of this type. */
+  Location getLocation() { result = this.getEntity().getLocation() }
+
   /**
+   * DEPRECATED: Use `getLocation()` instead.
+   *
    * Holds if this element is at the specified location.
    * The location spans column `startcolumn` of line `startline` to
    * column `endcolumn` of line `endline` in file `filepath`.
    * For more information, see
    * [Locations](https://codeql.github.com/docs/writing-codeql-queries/providing-locations-in-codeql-queries/).
    */
-  predicate hasLocationInfo(
+  deprecated predicate hasLocationInfo(
     string filepath, int startline, int startcolumn, int endline, int endcolumn
   ) {
-    this.getEntity().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
+    this.getLocation().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
     or
-    not exists(this.getEntity()) and
+    not exists(this.getLocation()) and
     filepath = "" and
     startline = 0 and
     startcolumn = 0 and

go/ql/lib/semmle/go/VariableWithFields.qll

@@ -183,16 +183,21 @@ class VariableWithFields extends TVariableWithFields {
    */
   string getElement() { this = TVariableElementStep(_, result) }
 
+  /** Gets the location of this variable with fields. */
+  Location getLocation() { result = this.getBaseVariable().getLocation() }
+
   /**
+   * DEPRECATED: Use `getLocation()` instead.
+   *
    * Holds if this element is at the specified location.
    * The location spans column `startcolumn` of line `startline` to
    * column `endcolumn` of line `endline` in file `filepath`.
    * For more information, see
    * [Locations](https://codeql.github.com/docs/writing-codeql-queries/providing-locations-in-codeql-queries/).
    */
-  predicate hasLocationInfo(
+  deprecated predicate hasLocationInfo(
     string filepath, int startline, int startcolumn, int endline, int endcolumn
   ) {
-    this.getBaseVariable().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
+    this.getLocation().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
   }
 }

go/ql/lib/semmle/go/controlflow/BasicBlocks.qll

@@ -114,17 +114,22 @@ class BasicBlock extends TControlFlowNode {
   /** Gets a textual representation of this basic block. */
   string toString() { result = "basic block" }
 
+  /** Gets the source location for this element. */
+  Location getLocation() { result = this.getFirstNode().getLocation() }
+
   /**
+   * DEPRECATED: Use `getLocation()` instead.
+   *
    * Holds if this basic block is at the specified location.
    * The location spans column `startcolumn` of line `startline` to
    * column `endcolumn` of line `endline` in file `filepath`.
    * For more information, see
    * [Locations](https://codeql.github.com/docs/writing-codeql-queries/providing-locations-in-codeql-queries/).
    */
-  predicate hasLocationInfo(
+  deprecated predicate hasLocationInfo(
     string filepath, int startline, int startcolumn, int endline, int endcolumn
   ) {
-    this.getFirstNode().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
+    this.getLocation().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
   }
 }
 

go/ql/lib/semmle/go/controlflow/ControlFlowGraph.qll

@@ -77,23 +77,31 @@ module ControlFlow {
     Root getRoot() { none() }
 
     /** Gets the file to which this node belongs. */
-    File getFile() { this.hasLocationInfo(result.getAbsolutePath(), _, _, _, _) }
+    File getFile() { result = this.getLocation().getFile() }
 
     /**
      * Gets a textual representation of this control flow node.
      */
     string toString() { result = "control-flow node" }
 
+    /** Gets the source location for this element. */
+    Location getLocation() { none() }
+
     /**
+     * DEPRECATED: Use `getLocation()` instead.
+     *
      * Holds if this element is at the specified location.
      * The location spans column `startcolumn` of line `startline` to
      * column `endcolumn` of line `endline` in file `filepath`.
      * For more information, see
      * [Locations](https://codeql.github.com/docs/writing-codeql-queries/providing-locations-in-codeql-queries/).
      */
-    predicate hasLocationInfo(
+    deprecated predicate hasLocationInfo(
       string filepath, int startline, int startcolumn, int endline, int endcolumn
     ) {
+      this.getLocation().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
+      or
+      not exists(this.getLocation()) and
       filepath = "" and
       startline = 0 and
       startcolumn = 0 and
@@ -244,11 +252,7 @@ module ControlFlow {
 
     override string toString() { result = cond + " is " + outcome }
 
-    override predicate hasLocationInfo(
-      string filepath, int startline, int startcolumn, int endline, int endcolumn
-    ) {
-      cond.hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
-    }
+    override Location getLocation() { result = cond.getLocation() }
   }
 
   /**

go/ql/lib/semmle/go/controlflow/ControlFlowGraphImpl.qll

@@ -418,11 +418,7 @@ class SkipNode extends ControlFlow::Node, MkSkipNode {
 
   override string toString() { result = "skip" }
 
-  override predicate hasLocationInfo(
-    string filepath, int startline, int startcolumn, int endline, int endcolumn
-  ) {
-    skip.hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
-  }
+  override Location getLocation() { result = skip.getLocation() }
 }
 
 /**
@@ -437,11 +433,7 @@ class EntryNode extends ControlFlow::Node, MkEntryNode {
 
   override string toString() { result = "entry" }
 
-  override predicate hasLocationInfo(
-    string filepath, int startline, int startcolumn, int endline, int endcolumn
-  ) {
-    root.hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
-  }
+  override Location getLocation() { result = root.getLocation() }
 }
 
 /**
@@ -456,11 +448,7 @@ class ExitNode extends ControlFlow::Node, MkExitNode {
 
   override string toString() { result = "exit" }
 
-  override predicate hasLocationInfo(
-    string filepath, int startline, int startcolumn, int endline, int endcolumn
-  ) {
-    root.hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
-  }
+  override Location getLocation() { result = root.getLocation() }
 }
 
 /**