add ql/repeated-word query

Author: erik-krogh

ql/ql/src/codeql_ql/ast/Ast.qll

@@ -178,6 +178,16 @@ class BlockComment extends TBlockComment, AstNode {
   override string getAPrimaryQlClass() { result = "BlockComment" }
 }
 
+class LineComment extends TLineComment, AstNode {
+  QL::LineComment comment;
+
+  LineComment() { this = TLineComment(comment) }
+
+  string getContents() { result = comment.getValue() }
+
+  override string getAPrimaryQlClass() { result = "LineComment" }
+}
+
 /**
  * The `from, where, select` part of a QL query.
  */

ql/ql/src/codeql_ql/ast/internal/AstNodes.qll

@@ -7,6 +7,7 @@ newtype TAstNode =
   TTopLevel(QL::Ql file) or
   TQLDoc(QL::Qldoc qldoc) or
   TBlockComment(QL::BlockComment comment) or
+  TLineComment(QL::LineComment comment) or
   TClasslessPredicate(QL::ClasslessPredicate pred) or
   TVarDecl(QL::VarDecl decl) or
   TFieldDecl(QL::Field field) or
@@ -154,6 +155,8 @@ QL::AstNode toQL(AST::AstNode n) {
   or
   n = TBlockComment(result)
   or
+  n = TLineComment(result)
+  or
   n = TClasslessPredicate(result)
   or
   n = TVarDecl(result)

ql/ql/src/queries/style/RepeatedWord.ql

@@ -0,0 +1,30 @@
+/**
+ * @name Comment has repeated word
+ * @description Comment has repeated word.
+ * @kind problem
+ * @problem.severity warning
+ * @id ql/repeated-word
+ * @precision very-high
+ */
+
+import ql
+
+string getComment(AstNode node) {
+  result = node.(QLDoc).getContents()
+  or
+  result = node.(BlockComment).getContents()
+  or
+  result = node.(LineComment).getContents()
+}
+
+/** Gets a word used in `node` */
+string getWord(AstNode node) { result = getComment(node).regexpFind("\\b[A-Za-z]+\\b", _, _) }
+
+AstNode hasRepeatedWord(string word) {
+  word = getWord(result) and
+  getComment(result).regexpMatch(".*\\b" + word + "\\s+" + word + "\\b.*")
+}
+
+from AstNode comment, string word
+where comment = hasRepeatedWord(word)
+select comment, "The comment repeats " + word + "."