Java: Add ModuleImportDeclaration QL class

Author: IdrissRio

java/ql/lib/semmle/code/java/Import.qll

@@ -6,6 +6,7 @@ module;
 
 import semmle.code.Location
 import CompilationUnit
+import Modules
 
 /** A common super-class for all kinds of Java import declarations. */
 class Import extends Element, @import {
@@ -154,3 +155,42 @@ class ImportStaticTypeMember extends Import {
 
   override string getAPrimaryQlClass() { result = "ImportStaticTypeMember" }
 }
+
+/**
+ * A module import declaration, which imports an entire module.
+ *
+ * For example, `import module java.base;`.
+ */
+class ModuleImportDeclaration extends Element, @moduleimportdeclaration {
+  /** Gets the compilation unit in which this module import declaration occurs. */
+  override CompilationUnit getCompilationUnit() { result = this.getFile() }
+
+  /** Holds if this module import declaration occurs in source code. */
+  override predicate fromSource() { any() }
+
+  /** Gets the name of the imported module. */
+  string getModuleName() { moduleImportDeclarations(this, _, result) }
+
+  /** Gets the imported module. */
+  Module getModule() { result.getName() = this.getModuleName() }
+
+  /** Gets an exported package from the imported module. */
+  Package getAnImportedPackage() {
+    exists(ExportsDirective exports |
+      exports = this.getModule().getADirective() and
+      result = exports.getExportedPackage()
+    )
+  }
+
+  /** Gets a type that is imported from the module. */
+  RefType getAnImportedType() {
+    exists(Package pkg |
+      pkg = this.getAnImportedPackage() and
+      result.getPackage() = pkg
+    )
+  }
+
+  override string toString() { result = "import module " + this.getModuleName() }
+
+  override string getAPrimaryQlClass() { result = "ModuleImportDeclaration" }
+}