Merge pull request #13715 from geoffw0/parsemode

Swift: Recognize regular expression parse mode flags

Author: geoffw0

swift/ql/lib/change-notes/2023-07-10-regex-mode-flags.md

@@ -0,0 +1,4 @@
+---
+category: minorAnalysis
+---
+* The regular expression library now understands mode flags specified at the beginning of a regular expression (for example `(?is)`).

swift/ql/lib/codeql/swift/regex/internal/ParseRegex.qll

@@ -16,17 +16,17 @@ abstract class RegExp extends Expr {
   /**
    * Holds if this `RegExp` has the `s` flag for multi-line matching.
    */
-  predicate isDotAll() { none() }
+  predicate isDotAll() { this.getAMode() = "DOTALL" }
 
   /**
    * Holds if this `RegExp` has the `i` flag for case-insensitive matching.
    */
-  predicate isIgnoreCase() { none() }
+  predicate isIgnoreCase() { this.getAMode() = "IGNORECASE" }
 
   /**
-   * Gets the flags for this `RegExp`, or the empty string if it has no flags.
+   * Gets a string representing the flags for this `RegExp`, or the empty string if it has no flags.
    */
-  string getFlags() { result = "" }
+  string getFlags() { result = concat(string mode | mode = this.getAMode() | mode, " | ") }
 
   /**
    * Helper predicate for `charSetStart(int start, int end)`.
@@ -274,6 +274,58 @@ abstract class RegExp extends Expr {
 
   private predicate isGroupStart(int i) { this.nonEscapedCharAt(i) = "(" and not this.inCharSet(i) }
 
+  /**
+   * Holds if a parse mode starts between `start` and `end`.
+   */
+  private predicate flagGroupStart(int start, int end) {
+    this.isGroupStart(start) and
+    this.getChar(start + 1) = "?" and
+    this.getChar(start + 2) in ["i", "x", "s", "m", "w"] and
+    end = start + 2
+  }
+
+  /**
+   * Holds if a parse mode group is between `start` and `end`, and includes the
+   * mode flag `c`. For example the following span, with mode flag `i`:
+   * ```
+   * (?i)
+   * ```
+   */
+  private predicate flagGroup(int start, int end, string c) {
+    exists(int inStart, int inEnd |
+      this.flagGroupStart(start, inStart) and
+      this.groupContents(start, end, inStart, inEnd) and
+      this.getChar([inStart .. inEnd - 1]) = c
+    )
+  }
+
+  /**
+   * Gets a mode of this regular expression string if it is defined by a mode prefix.
+   */
+  string getModeFromPrefix() {
+    exists(string c | this.flagGroup(_, _, c) |
+      c = "i" and result = "IGNORECASE" // case insensitive
+      or
+      c = "x" and result = "VERBOSE" // ignores whitespace and `#` comments within patterns
+      or
+      c = "s" and result = "DOTALL" // dot matches all characters, including line terminators
+      or
+      c = "m" and result = "MULTILINE" // `^` and `$` also match beginning and end of lines
+      or
+      c = "w" and result = "UNICODE" // Unicode UAX 29 word boundary mode
+    )
+  }
+
+  /**
+   * Gets a mode (if any) of this regular expression. Can be any of:
+   * IGNORECASE
+   * VERBOSE
+   * DOTALL
+   * MULTILINE
+   * UNICODE
+   */
+  string getAMode() { result = this.getModeFromPrefix() }
+
   /**
    * Holds if the `i`th character could not be parsed.
    */
@@ -653,6 +705,8 @@ abstract class RegExp extends Expr {
     this.commentGroupStart(start, end)
     or
     this.simpleGroupStart(start, end)
+    or
+    this.flagGroupStart(start, end)
   }
 
   /** Matches the start of a non-capturing group, e.g. `(?:` */