C#: Add more CIL consistency tests.

Author: calumgrant

csharp/ql/src/semmle/code/cil/ConsistencyChecks.qll

@@ -371,6 +371,19 @@ class TypeIsBothConstructedAndUnbound extends TypeViolation {
   override string getMessage() { result = "Type is both constructed and unbound" }
 }
 
+/**
+ * The location of a constructed generic type should be the same
+ * as the location of its unbound generic type.
+ */
+class InconsistentTypeLocation extends TypeViolation {
+  InconsistentTypeLocation() {
+    exists(this.getType().getLocation()) and
+    this.getType().getLocation() != this.getType().getSourceDeclaration().getLocation()
+  }
+
+  override string getMessage() { result = "Inconsistent constructed type location" }
+}
+
 /**
  * A constructed type that does not match its unbound generic type.
  */
@@ -403,6 +416,19 @@ class MethodViolation extends ConsistencyViolation, DeclarationCheck {
   override string getMessage() { none() }
 }
 
+/**
+ * The location of a constructed method should be equal to the
+ * location of its unbound generic.
+ */
+class InconsistentMethodLocation extends MethodViolation {
+  InconsistentMethodLocation() {
+    exists(this.getMethod().getLocation()) and
+    this.getMethod().getLocation() != this.getMethod().getSourceDeclaration().getLocation()
+  }
+
+  override string getMessage() { result = "Inconsistent constructed method location" }
+}
+
 /**
  * A constructed method that does not match its unbound method.
  */
@@ -431,7 +457,10 @@ abstract class MissingEntityViolation extends ConsistencyViolation, MissingEntit
  * The type `object` is missing from the database.
  */
 class MissingObjectViolation extends MissingEntityViolation {
-  MissingObjectViolation() { not exists(ObjectType o) }
+  MissingObjectViolation() {
+    exists(this) and
+    not exists(ObjectType o)
+  }
 
   override string getMessage() { result = "Object missing" }
 }
@@ -480,6 +509,43 @@ class ArrayTypeInvalidRank extends TypeViolation {
   override string getMessage() { result = "Invalid ArrayType.getRank()" }
 }
 
+/**
+ * A type should have at most one kind, except for missing referenced types
+ * where the interface/class is unknown.
+ */
+class KindViolation extends TypeViolation {
+  KindViolation() {
+    count(typeKind(this.getType())) != 1 and
+    exists(this.getType().getLocation())
+  }
+
+  override string getMessage() {
+    result = "Incorrect class/interface on type: " + concat(typeKind(this.getType()), " ")
+  }
+}
+
+/**
+ * The type of a kind must be consistent between a constructed generic and its
+ * unbound generic.
+ */
+class InconsistentKind extends TypeViolation {
+  InconsistentKind() { typeKind(this.getType()) != typeKind(this.getType().getSourceDeclaration()) }
+
+  override string getMessage() { result = "Inconsistent type kind of source declaration" }
+}
+
+private string typeKind(Type t) {
+  t instanceof Interface and result = "interface"
+  or
+  t instanceof Class and result = "class"
+  or
+  t instanceof TypeParameter and result = "type parameter"
+  or
+  t instanceof ArrayType and result = "array"
+  or
+  t instanceof PointerType and result = "pointer"
+}
+
 /**
  * A violation in a `Member`.
  */

csharp/ql/src/semmle/code/cil/Generics.qll

@@ -35,7 +35,13 @@ class UnboundGenericType extends UnboundGeneric, Type { }
 class UnboundGenericMethod extends UnboundGeneric, Method { }
 
 /** A constructed generic type. */
-class ConstructedType extends ConstructedGeneric, Type { }
+class ConstructedType extends ConstructedGeneric, Type {
+  final override UnboundGenericType getUnboundGeneric() { result = this.getUnboundType() }
+
+  override predicate isInterface() { this.getUnboundType().isInterface() }
+
+  override predicate isClass() { this.getUnboundType().isClass() }
+}
 
 /** A constructed generic method. */
 class ConstructedMethod extends ConstructedGeneric, Method {