JS: Add root dir to tsconfig model

Author: asgerf

javascript/ql/lib/semmle/javascript/TSConfig.qll

@@ -82,6 +82,49 @@ class TSConfig extends JsonObject {
     result = this.getAnIncludedContainer().getAChildContainer()
   }
 
+  /** Gets the path mentioned in the `rootDir` property. */
+  string getRootDirPath() { result = this.getCompilerOptions().getPropStringValue("rootDir") }
+
+  private Container getOwnRootDir() {
+    result = Resolver::resolve(this.getFolder(), this.getRootDirPath())
+  }
+
+  /** Gets the file or folder referenced by the `rootDir` property. */
+  Container getRootDir() {
+    result = this.getOwnRootDir()
+    or
+    not exists(this.getRootDirPath()) and
+    result = this.getExtendedTSConfig().getOwnRootDir()
+  }
+
+  private string getATopLevelIncludePath() {
+    result = this.getAnIncludePath().(FilePath).getComponent(0)
+  }
+
+  private string getUniqueTopLevelIncludePath() {
+    result = unique( | | this.getATopLevelIncludePath())
+  }
+
+  /**
+   * Gets the folder referred to by the `rootDir` property, or if absent, an effective root dir
+   * derived from `include` paths.
+   */
+  Container getEffectiveRootDir() {
+    result = this.getRootDir()
+    or
+    not exists(this.getRootDir()) and
+    (
+      result = this.getFolder().getFolder(this.getUniqueTopLevelIncludePath())
+      or
+      not exists(this.getUniqueTopLevelIncludePath()) and
+      exists(this.getATopLevelIncludePath()) and
+      result = this.getFolder()
+      or
+      not exists(this.getATopLevelIncludePath()) and
+      result = this.getExtendedTSConfig().getEffectiveRootDir()
+    )
+  }
+
   private JsonObject getPathMappings() { result = this.getCompilerOptions().getPropValue("paths") }
 
   /**
@@ -127,7 +170,8 @@ private module ResolverConfig implements Folder::ResolveSig {
   predicate shouldResolve(Container base, string path) {
     exists(TSConfig cfg |
       base = cfg.getFolder() and
-      path = [cfg.getExtendsPath(), cfg.getBaseUrlPath(), cfg.getAnIncludePath()]
+      path =
+        [cfg.getExtendsPath(), cfg.getBaseUrlPath(), cfg.getRootDirPath(), cfg.getAnIncludePath()]
     )
   }