Python: Adds modernizations and moves query over to them

Author: BekaValentine

python/ql/src/Exceptions/IllegalRaise.ql

@@ -15,7 +15,7 @@ import python
 import Raising
 import Exceptions.NotImplemented
 
-from Raise r, ClassObject t
-where type_or_typeof_objectapi(r, t, _) and not t.isLegalExceptionType() and not t.failedInference() and not use_of_not_implemented_in_raise(r, _)
+from Raise r, ClassValue t
+where type_or_typeof(r, t, _) and not t.isLegalExceptionType() and not t.failedInference(_) and not use_of_not_implemented_in_raise(r, _)
 select r, "Illegal class '" + t.getName() + "' raised; will result in a TypeError being raised instead."
 

python/ql/src/Exceptions/Raising.qll

@@ -12,3 +12,18 @@ predicate type_or_typeof_objectapi(Raise r, ClassObject type, AstNode orig) {
     )
 
 }
+
+/** Whether the raise statement 'r' raises 'type' from origin 'orig' */ 
+predicate type_or_typeof(Raise r, ClassValue type, AstNode orig) {
+     exists(Expr exception |
+        exception = r.getRaised() |
+        exception.pointsTo(type, orig)
+        or
+        not exists(ClassValue exc_type | exception.pointsTo(exc_type)) and
+        not type = ClassValue::type() and // First value is an unknown exception type
+        exists(Value val | exception.pointsTo(val, orig) |
+          val.getClass() = type
+        )
+    )
+
+}

python/ql/src/semmle/python/objects/ObjectAPI.qll

@@ -481,6 +481,15 @@ class ClassValue extends Value {
     predicate declaresAttribute(string name) {
         this.(ClassObjectInternal).getClassDeclaration().declaresAttribute(name)
     }
+    
+    /** Whether this class is a legal exception class. 
+     *  What constitutes a legal exception class differs between major versions */
+    predicate isLegalExceptionType() {
+        not this.isNewStyle() or
+        this.getASuperType() = ClassValue::baseException()
+        or
+        major_version() = 2 and this = ClassValue::tuple()
+    }
 
 }