Rust: Factor out getTypeMentionForTypeParameter

Author: paldepind

rust/ql/lib/codeql/rust/internal/TypeMention.qll

@@ -61,13 +61,14 @@ class PathTypeMention extends TypeMention, Path {
 
   TypeItemNode getResolved() { result = resolved }
 
+  /**
+   * Gets a type alias with the name `name` of the trait that this path resolves
+   * to, if any.
+   */
   pragma[nomagic]
   private TypeAlias getResolvedTraitAlias(string name) {
-    exists(TraitItemNode trait |
-      trait = resolved and
-      result = trait.getAnAssocItem() and
-      name = result.getName().getText()
-    )
+    result = resolved.(TraitItemNode).getAnAssocItem() and
+    name = result.getName().getText()
   }
 
   pragma[nomagic]
@@ -140,40 +141,18 @@ class PathTypeMention extends TypeMention, Path {
     )
   }
 
-  override Type resolveTypeAt(TypePath typePath) {
-    result = this.aliasResolveTypeAt(typePath)
-    or
-    typePath.isEmpty() and
-    (
-      result = TStruct(resolved)
-      or
-      result = TEnum(resolved)
-      or
-      exists(TraitItemNode trait | trait = resolved |
-        // If this is a `Self` path, then it resolves to the implicit `Self`
-        // type parameter, otherwise it is a trait bound.
-        if this = trait.getASelfPath()
-        then result = TSelfTypeParameter(trait)
-        else result = TTrait(trait)
-      )
-      or
-      result = TTypeParamTypeParameter(resolved)
-      or
-      result = TAssociatedTypeTypeParameter(resolved)
-    )
-    or
+  /** Gets the type mention in this path for the type parameter `tp`, if any. */
+  pragma[nomagic]
+  private TypeMention getTypeMentionForTypeParameter(TypeParameter tp) {
     not exists(resolved.(TypeAlias).getTypeRepr()) and
-    exists(TypeParameter tp, TypeMention arg, TypePath suffix |
-      result = arg.resolveTypeAt(suffix) and
-      typePath = TypePath::cons(tp, suffix)
-    |
+    (
       exists(int i |
-        arg = this.getPositionalTypeArgument(pragma[only_bind_into](i)) and
+        result = this.getPositionalTypeArgument(pragma[only_bind_into](i)) and
         tp = this.resolveType().getTypeParameter(pragma[only_bind_into](i))
       )
       or
       exists(TypeAlias alias |
-        arg = this.getAnAssocTypeArgument(alias) and
+        result = this.getAnAssocTypeArgument(alias) and
         tp = TAssociatedTypeTypeParameter(alias)
       )
       or
@@ -195,14 +174,42 @@ class PathTypeMention extends TypeMention, Path {
         param.getTrait() = resolved and
         name = param.getTypeAlias().getName().getText() and
         alias = impl.getASuccessor(pragma[only_bind_into](name)) and
-        arg = alias.getTypeRepr() and
+        result = alias.getTypeRepr() and
         tp =
           TAssociatedTypeTypeParameter(resolved
                 .(TraitItemNode)
                 .getAssocItem(pragma[only_bind_into](name)))
       )
     )
   }
+
+  override Type resolveTypeAt(TypePath typePath) {
+    result = this.aliasResolveTypeAt(typePath)
+    or
+    typePath.isEmpty() and
+    (
+      result = TStruct(resolved)
+      or
+      result = TEnum(resolved)
+      or
+      exists(TraitItemNode trait | trait = resolved |
+        // If this is a `Self` path, then it resolves to the implicit `Self`
+        // type parameter, otherwise it is a trait bound.
+        if this = trait.getASelfPath()
+        then result = TSelfTypeParameter(trait)
+        else result = TTrait(trait)
+      )
+      or
+      result = TTypeParamTypeParameter(resolved)
+      or
+      result = TAssociatedTypeTypeParameter(resolved)
+    )
+    or
+    exists(TypeParameter tp, TypePath suffix |
+      result = this.getTypeMentionForTypeParameter(tp).resolveTypeAt(suffix) and
+      typePath = TypePath::cons(tp, suffix)
+    )
+  }
 }
 
 class PathTypeReprMention extends TypeMention, PathTypeRepr {