JS: Update implementation

Author: asgerf

javascript/ql/lib/semmle/javascript/internal/paths/JSPaths.qll

@@ -43,15 +43,11 @@ module JSPaths {
     //
     //   { include: ["foo"], compilerOptions: { outDir: "./bar" }}
     //
-    exists(TSConfig tsconfig, Container includeTarget |
+    exists(TSConfig tsconfig |
       name =
         tsconfig.getCompilerOptions().getPropStringValue("outDir").regexpReplaceAll("^\\./", "") and
       base = tsconfig.getFolder() and
-      includeTarget = tsconfig.getAnIncludePathTarget()
-    |
-      result = includeTarget.(Folder)
-      or
-      result = includeTarget.(File).getParentContainer()
+      result = tsconfig.getEffectiveRootDir()
     )
     or
     // Heuristic version of the above based on commonly used source and build folder names

javascript/ql/lib/semmle/javascript/internal/paths/PackageJsonEx.qll

@@ -52,13 +52,34 @@ class PackageJsonEx extends PackageJson {
     )
   }
 
+  File getMainFileOrBestGuess() {
+    result = this.getMainFile()
+    or
+    result = guessPackageJsonMain1(this)
+    or
+    result = guessPackageJsonMain2(this)
+  }
+
   string getAPathInFilesArray() {
     result = this.getPropValue("files").(JsonArray).getElementStringValue(_)
   }
 
   Container getAFileInFilesArray() {
     result = Resolver::resolve(this.getFolder(), this.getAPathInFilesArray())
   }
+
+  override File getTypingsFile() {
+    result = Resolver::resolve(this.getFolder(), this.getTypings())
+    or
+    not exists(this.getTypings()) and
+    exists(File mainFile |
+      mainFile = this.getMainFileOrBestGuess() and
+      result =
+        mainFile
+            .getParentContainer()
+            .getFile(mainFile.getStem().regexpReplaceAll("\\.d$", "") + ".d.ts")
+    )
+  }
 }
 
 private module ResolverConfig implements Folder::ResolveSig {
@@ -72,6 +93,8 @@ private module ResolverConfig implements Folder::ResolveSig {
       path = pkg.getMainPath()
       or
       path = pkg.getAPathInFilesArray()
+      or
+      path = pkg.getTypings()
     )
   }
 
@@ -80,6 +103,43 @@ private module ResolverConfig implements Folder::ResolveSig {
   predicate getAnAdditionalChild = JSPaths::getAnAdditionalChild/2;
 
   predicate isOptionalPathComponent(string segment) { segment = ["cjs", "mjs", "js"] }
+
+  bindingset[segment]
+  string rewritePathSegment(string segment) { result = segment.regexpReplaceAll("\\..*", "") }
 }
 
 private module Resolver = Folder::Resolve<ResolverConfig>;
+
+/**
+ * Removes the scope from a package name, e.g. `@foo/bar` -> `bar`.
+ */
+bindingset[name]
+private string stripPackageScope(string name) { result = name.regexpReplaceAll("^@[^/]+/", "") }
+
+private predicate isImplementationFile(File f) { not f.getBaseName().matches("%.d.ts") }
+
+File guessPackageJsonMain1(PackageJsonEx pkg) {
+  not isImplementationFile(pkg.getMainFile()) and
+  exists(Folder folder, Folder subfolder |
+    folder = pkg.getFolder() and
+    (
+      subfolder = folder or
+      subfolder = folder.getChildContainer(getASrcFolderName()) or
+      subfolder =
+        folder
+            .getChildContainer(getASrcFolderName())
+            .(Folder)
+            .getChildContainer(getASrcFolderName())
+    )
+  |
+    result = subfolder.getJavaScriptFileOrTypings("index")
+    or
+    result = subfolder.getJavaScriptFileOrTypings(stripPackageScope(pkg.getDeclaredPackageName()))
+  )
+}
+
+File guessPackageJsonMain2(PackageJsonEx pkg) {
+  not isImplementationFile(pkg.getMainFile()) and
+  not isImplementationFile(guessPackageJsonMain1(pkg)) and
+  result = pkg.getAFileInFilesArray()
+}

javascript/ql/lib/semmle/javascript/internal/paths/PathConcatenation.qll

@@ -0,0 +1,35 @@
+private import javascript
+
+/**
+ * A path expression that can be constant-folded by concatenating subexpressions.
+ */
+abstract class PathConcatenation extends Expr {
+  /** Gets the separator to insert between paths */
+  string getSeparator() { result = "" }
+
+  /** Gets the `n`th operand to concatenate. */
+  abstract Expr getOperand(int n);
+}
+
+private class AddExprConcatenation extends PathConcatenation, AddExpr {
+  override Expr getOperand(int n) {
+    n = 0 and result = this.getLeftOperand()
+    or
+    n = 1 and result = this.getRightOperand()
+  }
+}
+
+private class TemplateConcatenation extends PathConcatenation, TemplateLiteral {
+  override Expr getOperand(int n) { result = this.getElement(n) }
+}
+
+private class JoinCallConcatenation extends PathConcatenation, CallExpr {
+  JoinCallConcatenation() {
+    this.getReceiver().(VarAccess).getName() = "path" and
+    this.getCalleeName() = ["join", "resolve"]
+  }
+
+  override Expr getOperand(int n) { result = this.getArgument(n) }
+
+  override string getSeparator() { result = "/" }
+}