Brought back FunctionStyleClass marked as deprecated

Author: Napalys

javascript/ql/lib/semmle/javascript/dataflow/Nodes.qll

@@ -1236,6 +1236,129 @@ module ClassNode {
     func instanceof AbstractCallable // the join-order goes bad if `func` has type `AbstractFunction`.
   }
 
+  /**
+   * A function definition, targeted by a `new`-call or with prototype manipulation, seen as a `ClassNode` instance.
+   */
+  deprecated class FunctionStyleClass extends Range, DataFlow::ValueNode {
+    override Function astNode;
+    AbstractFunction function;
+
+    FunctionStyleClass() {
+      function.getFunction() = astNode and
+      (
+        exists(getAFunctionValueWithPrototype(function))
+        or
+        function = any(NewNode new).getCalleeNode().analyze().getAValue()
+        or
+        exists(string name | this = AccessPath::getAnAssignmentTo(name) |
+          exists(getAPrototypeReferenceInFile(name, this.getFile()))
+          or
+          exists(getAnInstantiationInFile(name, this.getFile()))
+        )
+      )
+    }
+
+    override string getName() { result = astNode.getName() }
+
+    override string describe() { result = astNode.describe() }
+
+    override FunctionNode getConstructor() { result = this }
+
+    private PropertyAccessor getAnAccessor(MemberKind kind) {
+      result.getObjectExpr() = this.getAPrototypeReference().asExpr() and
+      (
+        kind = MemberKind::getter() and
+        result instanceof PropertyGetter
+        or
+        kind = MemberKind::setter() and
+        result instanceof PropertySetter
+      )
+    }
+
+    override FunctionNode getInstanceMember(string name, MemberKind kind) {
+      kind = MemberKind::method() and
+      result = this.getAPrototypeReference().getAPropertySource(name)
+      or
+      kind = MemberKind::method() and
+      result = this.getConstructor().getReceiver().getAPropertySource(name)
+      or
+      exists(PropertyAccessor accessor |
+        accessor = this.getAnAccessor(kind) and
+        accessor.getName() = name and
+        result = accessor.getInit().flow()
+      )
+    }
+
+    override FunctionNode getAnInstanceMember(MemberKind kind) {
+      kind = MemberKind::method() and
+      result = this.getAPrototypeReference().getAPropertySource()
+      or
+      kind = MemberKind::method() and
+      result = this.getConstructor().getReceiver().getAPropertySource()
+      or
+      exists(PropertyAccessor accessor |
+        accessor = this.getAnAccessor(kind) and
+        result = accessor.getInit().flow()
+      )
+    }
+
+    override FunctionNode getStaticMember(string name, MemberKind kind) {
+      kind.isMethod() and
+      result = this.getAPropertySource(name)
+    }
+
+    override FunctionNode getAStaticMember(MemberKind kind) {
+      kind.isMethod() and
+      result = this.getAPropertySource()
+    }
+
+    /**
+     * Gets a reference to the prototype of this class.
+     */
+    DataFlow::SourceNode getAPrototypeReference() {
+      exists(DataFlow::SourceNode base | base = getAFunctionValueWithPrototype(function) |
+        result = base.getAPropertyRead("prototype")
+        or
+        result = base.getAPropertySource("prototype")
+      )
+      or
+      exists(string name |
+        this = AccessPath::getAnAssignmentTo(name) and
+        result = getAPrototypeReferenceInFile(name, this.getFile())
+      )
+      or
+      exists(ExtendCall call |
+        call.getDestinationOperand() = this.getAPrototypeReference() and
+        result = call.getASourceOperand()
+      )
+    }
+
+    override DataFlow::Node getASuperClassNode() {
+      // C.prototype = Object.create(D.prototype)
+      exists(DataFlow::InvokeNode objectCreate, DataFlow::PropRead superProto |
+        this.getAPropertySource("prototype") = objectCreate and
+        objectCreate = DataFlow::globalVarRef("Object").getAMemberCall("create") and
+        superProto.flowsTo(objectCreate.getArgument(0)) and
+        superProto.getPropertyName() = "prototype" and
+        result = superProto.getBase()
+      )
+      or
+      // C.prototype = new D()
+      exists(DataFlow::NewNode newCall |
+        this.getAPropertySource("prototype") = newCall and
+        result = newCall.getCalleeNode()
+      )
+      or
+      // util.inherits(C, D);
+      exists(DataFlow::CallNode inheritsCall |
+        inheritsCall = DataFlow::moduleMember("util", "inherits").getACall()
+      |
+        this = inheritsCall.getArgument(0).getALocalSource() and
+        result = inheritsCall.getArgument(1)
+      )
+    }
+  }
+
   /**
    * A function definition, targeted by a `new`-call or with prototype manipulation, seen as a `ClassNode` instance.
    * Or An ES6 class as a `ClassNode` instance.