Re-factor TestOutput into a param module.

Author: michaelnebel

csharp/ql/test/library-tests/dataflow/library/FlowSummaries.ql

@@ -1,14 +1,17 @@
 import shared.FlowSummaries
 import semmle.code.csharp.dataflow.internal.ExternalFlow
-import semmle.code.csharp.dataflow.internal.FlowSummaryImpl::Private::External
+import External
 
-private class IncludeAllSummarizedCallable extends IncludeSummarizedCallable {
-  IncludeAllSummarizedCallable() { exists(this) }
+module TestSummaryInput implements TestSummaryInputSig {
+  class RelevantSummarizedCallable = IncludeSummarizedCallable;
 }
 
-private class IncludeNeutralSummarizedCallable extends RelevantNeutralCallable {
-  /** Gets a string representing the callable in semi-colon separated format for use in flow summaries. */
-  final override string getCallableCsv() { result = asPartialNeutralModel(this) }
+module TestNeutralInput implements TestNeutralInputSig {
+  class RelevantNeutralCallable instanceof NeutralCallable {
+    final string getCallableCsv() { result = asPartialNeutralModel(this) }
+
+    string toString() { result = super.toString() }
+  }
 }
 
 module TestSourceSinkInput implements TestSourceSinkInputSig {
@@ -25,4 +28,6 @@ module TestSourceSinkInput implements TestSourceSinkInputSig {
   }
 }
 
+import TestSummaryOutput<TestSummaryInput>
+import TestNeutralOutput<TestNeutralInput>
 import TestSourceSinkOutput<TestSourceSinkInput>

csharp/ql/test/library-tests/dataflow/library/FlowSummariesFiltered.ql

@@ -1,9 +1,13 @@
 import shared.FlowSummaries
 private import semmle.code.csharp.dataflow.internal.ExternalFlow
 
-class IncludeFilteredSummarizedCallable extends IncludeSummarizedCallable {
-  IncludeFilteredSummarizedCallable() { exists(this) }
+module TestSummaryInput implements TestSummaryInputSig {
+  class RelevantSummarizedCallable = IncludeSummarizedCallable;
+}
+
+import TestSummaryOutput<TestSummaryInput>
 
+class IncludeFilteredSummarizedCallable extends RelevantSummarizedCallable {
   /**
    * Holds if flow is propagated between `input` and `output` and
    * if there is no summary for a callable in a `base` class or interface
@@ -12,10 +16,10 @@ class IncludeFilteredSummarizedCallable extends IncludeSummarizedCallable {
   override predicate relevantSummary(
     SummaryComponentStack input, SummaryComponentStack output, boolean preservesValue
   ) {
-    super.propagatesFlow(input, output, preservesValue) and
+    this.(SummarizedCallableImpl).propagatesFlow(input, output, preservesValue) and
     not exists(IncludeSummarizedCallable rsc |
       isBaseCallableOrPrototype(rsc) and
-      rsc.propagatesFlow(input, output, preservesValue) and
+      rsc.(SummarizedCallableImpl).propagatesFlow(input, output, preservesValue) and
       this.(UnboundCallable).overridesOrImplementsUnbound(rsc)
     )
   }

csharp/ql/test/library-tests/frameworks/EntityFramework/FlowSummaries.ql

@@ -3,8 +3,12 @@ import shared.FlowSummaries
 import semmle.code.csharp.frameworks.EntityFramework::EntityFramework
 import semmle.code.csharp.dataflow.internal.ExternalFlow as ExternalFlow
 
-private class IncludeEFSummarizedCallable extends IncludeSummarizedCallable instanceof EFSummarizedCallable
-{ }
+module TestSummaryInput implements TestSummaryInputSig {
+  class RelevantSummarizedCallable extends IncludeSummarizedCallable instanceof EFSummarizedCallable
+  { }
+}
+
+import TestSummaryOutput<TestSummaryInput>
 
 query predicate sourceNode(DataFlow::Node node, string kind) {
   ExternalFlow::sourceNode(node, kind)

csharp/ql/test/shared/FlowSummaries.qll

@@ -1,13 +1,14 @@
 import semmle.code.csharp.dataflow.internal.FlowSummaryImpl::Private
 import semmle.code.csharp.dataflow.internal.FlowSummaryImpl::Public
-import semmle.code.csharp.dataflow.internal.FlowSummaryImpl::Private::TestOutput
 private import semmle.code.csharp.dataflow.internal.ExternalFlow
 
-abstract class IncludeSummarizedCallable extends RelevantSummarizedCallable {
+class IncludeSummarizedCallable instanceof SummarizedCallableImpl {
   IncludeSummarizedCallable() {
     [this.(Modifiable), this.(Accessor).getDeclaration()].isEffectivelyPublic()
   }
 
   /** Gets a string representing the callable in semi-colon separated format for use in flow summaries. */
-  final override string getCallableCsv() { result = asPartialModel(this) }
+  final string getCallableCsv() { result = asPartialModel(this) }
+
+  string toString() { result = super.toString() }
 }

shared/dataflow/codeql/dataflow/internal/FlowSummaryImpl.qll

@@ -1751,32 +1751,31 @@ module Make<DF::InputSig DataFlowLang, InputSig<DataFlowLang> Input> {
       }
     }
 
+    signature module TestSummaryInputSig {
+      /**
+       * A class of callables where the flow summary should be included
+       * in the `summary/1` query predicate.
+       */
+      class RelevantSummarizedCallable instanceof SummarizedCallableImpl {
+        /** Gets the string representation of this callable used by `summary/1`. */
+        string getCallableCsv();
+      }
+    }
+
     /** Provides a query predicate for outputting a set of relevant flow summaries. */
-    module TestOutput {
-      final private class SummarizedCallableImplFinal = SummarizedCallableImpl;
+    module TestSummaryOutput<TestSummaryInputSig TestInput> {
+      private import TestInput
 
-      /** A flow summary to include in the `summary/1` query predicate. */
-      abstract class RelevantSummarizedCallable extends SummarizedCallableImplFinal {
-        /** Gets the string representation of this callable used by `summary/1`. */
-        abstract string getCallableCsv();
+      final class RelevantSummarizedCallableFinal = TestInput::RelevantSummarizedCallable;
 
+      class RelevantSummarizedCallable extends RelevantSummarizedCallableFinal instanceof SummarizedCallableImpl
+      {
         /** Holds if flow is propagated between `input` and `output`. */
         predicate relevantSummary(
           SummaryComponentStack input, SummaryComponentStack output, boolean preservesValue
         ) {
           super.propagatesFlow(input, output, preservesValue)
         }
-      }
-
-      /** A model to include in the `neutral/1` query predicate. */
-      abstract class RelevantNeutralCallable instanceof NeutralCallable {
-        /** Gets the string representation of this callable used by `neutral/1`. */
-        abstract string getCallableCsv();
-
-        /**
-         * Gets the kind of the neutral.
-         */
-        string getKind() { result = super.getKind() }
 
         string toString() { result = super.toString() }
       }
@@ -1795,13 +1794,6 @@ module Make<DF::InputSig DataFlowLang, InputSig<DataFlowLang> Input> {
         c.hasProvenance(result)
       }
 
-      private string renderProvenanceNeutral(NeutralCallable c) {
-        exists(Provenance p | p.isManual() and c.hasProvenance(p) and result = p.toString())
-        or
-        not c.hasManualModel() and
-        c.hasProvenance(result)
-      }
-
       /**
        * Holds if there exists a relevant summary callable with information roughly corresponding to `csv`.
        * Used for testing.
@@ -1822,6 +1814,39 @@ module Make<DF::InputSig DataFlowLang, InputSig<DataFlowLang> Input> {
               + renderProvenance(c) // provenance
         )
       }
+    }
+
+    signature module TestNeutralInputSig {
+      /**
+       * A class of callables where the neutral model should be included
+       * in the `neutral/1` query predicate.
+       */
+      class RelevantNeutralCallable instanceof NeutralCallable {
+        /** Gets the string representation of this callable used by `neutral/1`. */
+        string getCallableCsv();
+      }
+    }
+
+    module TestNeutralOutput<TestNeutralInputSig TestInput> {
+      private import TestInput
+
+      final class RelevantNeutralCallableFinal = TestInput::RelevantNeutralCallable;
+
+      class RelevantNeutralCallable extends RelevantNeutralCallableFinal instanceof NeutralCallable {
+        /**
+         * Gets the kind of the neutral.
+         */
+        string getKind() { result = super.getKind() }
+
+        string toString() { result = super.toString() }
+      }
+
+      private string renderProvenance(NeutralCallable c) {
+        exists(Provenance p | p.isManual() and c.hasProvenance(p) and result = p.toString())
+        or
+        not c.hasManualModel() and
+        c.hasProvenance(result)
+      }
 
       /**
        * Holds if there exists a relevant neutral callable with information roughly corresponding to `csv`.
@@ -1833,7 +1858,7 @@ module Make<DF::InputSig DataFlowLang, InputSig<DataFlowLang> Input> {
           csv =
             c.getCallableCsv() // Callable information
               + c.getKind() + ";" // kind
-              + renderProvenanceNeutral(c) // provenance
+              + renderProvenance(c) // provenance
         )
       }
     }