JS: Update handling of JSDoc comments

Author: asgerf

javascript/ql/lib/semmle/javascript/JSDoc.qll

@@ -33,6 +33,9 @@ class JSDoc extends @jsdoc, Locatable {
     result.getTitle() = title
   }
 
+  /** Gets the element to which this JSDoc comment is attached */
+  Documentable getDocumentedElement() { result.getDocumentation() = this }
+
   override string toString() { result = this.getComment().toString() }
 }
 
@@ -299,6 +302,41 @@ class JSDocIdentifierTypeExpr extends @jsdoc_identifier_type_expr, JSDocTypeExpr
   override predicate isRawFunction() { this.getName() = "Function" }
 }
 
+private AstNode getAncestorInScope(Documentable doc) {
+  any(JSDocLocalTypeAccess t).getJSDocComment() = doc.getDocumentation() and // restrict to cases where we need this
+  result = doc.getParent()
+  or
+  exists(AstNode mid |
+    mid = getAncestorInScope(doc) and
+    not mid = any(Scope s).getScopeElement() and
+    result = mid.getParent()
+  )
+}
+
+private Scope getScope(Documentable doc) { result.getScopeElement() = getAncestorInScope(doc) }
+
+pragma[nomagic]
+private predicate shouldResolveName(TopLevel top, string name) {
+  exists(JSDocLocalTypeAccess access |
+    access.getName() = name and
+    access.getTopLevel() = top
+  )
+}
+
+private LexicalName getOwnLocal(Scope scope, string name, DeclarationSpace space) {
+  scope = result.getScope() and
+  name = result.getName() and
+  space = result.getDeclarationSpace() and
+  shouldResolveName(scope.getScopeElement().getTopLevel(), name) // restrict size of predicate
+}
+
+private LexicalName resolveLocal(Scope scope, string name, DeclarationSpace space) {
+  result = getOwnLocal(scope, name, space)
+  or
+  result = resolveLocal(scope.getOuterScope(), name, space) and
+  not exists(getOwnLocal(scope, name, space))
+}
+
 /**
  * An unqualified identifier in a JSDoc type expression.
  *
@@ -311,6 +349,12 @@ class JSDocIdentifierTypeExpr extends @jsdoc_identifier_type_expr, JSDocTypeExpr
  */
 class JSDocLocalTypeAccess extends JSDocIdentifierTypeExpr {
   JSDocLocalTypeAccess() { not this = any(JSDocQualifiedTypeAccess a).getNameNode() }
+
+  /** Gets a variable, type-name, or namespace that this expression may resolve to. */
+  LexicalName getALexicalName() {
+    result =
+      resolveLocal(getScope(this.getJSDocComment().getDocumentedElement()), this.getName(), _)
+  }
 }
 
 /**

javascript/ql/lib/semmle/javascript/internal/NameResolution.qll

@@ -137,12 +137,6 @@ module NameResolution {
       node1 = type.getExpressionName() and
       node2 = type
     )
-    or
-    exists(JSDocNamedTypeExpr type, string name |
-      type.hasNameParts(name, "") and
-      node1 = type.getTopLevel().getScope().getLocalTypeName(name) and
-      node2 = type
-    )
   }
 
   /**
@@ -186,11 +180,9 @@ module NameResolution {
       node2 = spec.getLocal()
     )
     or
-    // Support JSDoc expressions of the form 'foo.bar' where 'foo' is an import
-    // at the top-level.
-    exists(JSDocNamedTypeExpr expr, string prefix |
-      expr.hasNameParts(prefix, "." + name) and
-      node1 = expr.getTopLevel().getScope().getVariable(prefix) and
+    exists(JSDocQualifiedTypeAccess expr |
+      node1 = expr.getBase() and
+      name = expr.getName() and
       node2 = expr
     )
   }
@@ -277,6 +269,9 @@ module NameResolution {
         or
         node1 = var and
         node2.(LexicalAccess).getALexicalName() = var
+        or
+        node1 = var and
+        node2.(JSDocLocalTypeAccess).getALexicalName() = var
       )
       or
       exists(Node base, string name, ModuleLike mod |

javascript/ql/lib/semmle/javascript/internal/UnderlyingTypes.qll

@@ -74,9 +74,11 @@ module UnderlyingTypes {
   predicate nodeHasUnderlyingType(Node node, string mod, string name) {
     nodeRefersToModule(node, mod, name)
     or
-    exists(JSDocNamedTypeExpr type |
+    exists(JSDocLocalTypeAccess type |
       node = type and
-      type.hasQualifiedName(name) and
+      not exists(type.getALexicalName()) and
+      not type = any(JSDocQualifiedTypeAccess t).getBase() and
+      name = type.getName() and
       mod = "global"
     )
     or

javascript/ql/test/library-tests/UnderlyingTypes/jsdoc.js

@@ -4,11 +4,11 @@ import { Response } from 'express';
 /**
  * @param {e.Request} req
  */
-function t1(req) { // $ hasUnderlyingType='express'.Request SPURIOUS: hasUnderlyingType=e.Request
+function t1(req) { // $ hasUnderlyingType='express'.Request
 }
 
 /**
  * @param {Response} res
  */
-function t2(res) { // $ hasUnderlyingType='express'.Response SPURIOUS: hasUnderlyingType=Response
+function t2(res) { // $ hasUnderlyingType='express'.Response
 }