Rust: Handle chained let expressions

Author: hvitved

rust/ql/lib/codeql/rust/controlflow/internal/CfgNodes.qll

@@ -7,8 +7,7 @@ private import codeql.rust.controlflow.CfgNodes
 private import codeql.rust.internal.CachedStages
 
 private predicate isPostOrder(AstNode n) {
-  n instanceof Expr and
-  not n instanceof LetExpr
+  n instanceof Expr
   or
   n instanceof OrPat
   or

rust/ql/lib/codeql/rust/controlflow/internal/ControlFlowGraphImpl.qll

@@ -200,8 +200,7 @@ class TypeReprTree extends LeafTree instanceof TypeRepr { }
 /**
  * Provides `ControlFlowTree`s for expressions.
  *
- * Since expressions construct values, they are modeled in post-order, except for
- * `LetExpr`s.
+ * Since expressions construct values, they are modeled in post-order.
  */
 module ExprTrees {
   class ArrayExprTree extends StandardPostOrderTree, ArrayExpr {
@@ -341,21 +340,15 @@ module ExprTrees {
       child = [super.getCondition(), super.getABranch()]
     }
 
-    private ConditionalCompletion conditionCompletion(Completion c) {
-      if super.getCondition() instanceof LetExpr
-      then result = c.(MatchCompletion)
-      else result = c.(BooleanCompletion)
-    }
-
     override predicate succ(AstNode pred, AstNode succ, Completion c) {
       // Edges from the condition to the branches
       last(super.getCondition(), pred, c) and
       (
-        first(super.getThen(), succ) and this.conditionCompletion(c).succeeded()
+        first(super.getThen(), succ) and c.(ConditionalCompletion).succeeded()
         or
-        first(super.getElse(), succ) and this.conditionCompletion(c).failed()
+        first(super.getElse(), succ) and c.(ConditionalCompletion).failed()
         or
-        not super.hasElse() and succ = this and this.conditionCompletion(c).failed()
+        not super.hasElse() and succ = this and c.(ConditionalCompletion).failed()
       )
       or
       // An edge from the then branch to the last node
@@ -401,10 +394,7 @@ module ExprTrees {
     }
   }
 
-  // `LetExpr` is a pre-order tree such that the pattern itself ends up
-  // dominating successors in the graph in the same way that patterns do in
-  // `match` expressions.
-  class LetExprTree extends StandardPreOrderTree, LetExpr {
+  class LetExprTree extends StandardPostOrderTree, LetExpr {
     override AstNode getChildNode(int i) {
       i = 0 and
       result = this.getScrutinee()
@@ -456,21 +446,15 @@ module ExprTrees {
 
     override predicate first(AstNode node) { first(super.getCondition(), node) }
 
-    private ConditionalCompletion conditionCompletion(Completion c) {
-      if super.getCondition() instanceof LetExpr
-      then result = c.(MatchCompletion)
-      else result = c.(BooleanCompletion)
-    }
-
     override predicate succ(AstNode pred, AstNode succ, Completion c) {
       super.succ(pred, succ, c)
       or
       last(super.getCondition(), pred, c) and
-      this.conditionCompletion(c).succeeded() and
+      c.(ConditionalCompletion).succeeded() and
       first(this.getLoopBody(), succ)
       or
       last(super.getCondition(), pred, c) and
-      this.conditionCompletion(c).failed() and
+      c.(ConditionalCompletion).failed() and
       succ = this
     }
   }

rust/ql/lib/codeql/rust/controlflow/internal/Splitting.qll

@@ -71,13 +71,7 @@ module ConditionalCompletionSplitting {
       child = parent.(LogicalNotExpr).getExpr() and
       childCompletion.getDual() = parentCompletion
       or
-      (
-        childCompletion = parentCompletion
-        or
-        // needed for `let` expressions
-        childCompletion.(MatchCompletion).getValue() =
-          parentCompletion.(BooleanCompletion).getValue()
-      ) and
+      childCompletion = parentCompletion and
       (
         child = parent.(BinaryLogicalOperation).getAnOperand()
         or
@@ -92,6 +86,9 @@ module ConditionalCompletionSplitting {
         or
         child = parent.(PatternTrees::PostOrderPatTree).getPat(_)
       )
+      or
+      child = parent.(LetExpr).getPat() and
+      childCompletion.(MatchCompletion).getValue() = parentCompletion.(BooleanCompletion).getValue()
     }
   }
 

rust/ql/lib/codeql/rust/dataflow/Ssa.qll

@@ -194,9 +194,16 @@ module Ssa {
         ae.getRhs() = value
       )
       or
-      exists(LetStmtCfgNode ls |
-        ls.getPat().(IdentPatCfgNode).getName() = write and
-        ls.getInitializer() = value
+      exists(IdentPatCfgNode pat | pat.getName() = write |
+        exists(LetStmtCfgNode ls |
+          pat = ls.getPat() and
+          ls.getInitializer() = value
+        )
+        or
+        exists(LetExprCfgNode le |
+          pat = le.getPat() and
+          le.getScrutinee() = value
+        )
       )
     }
 

rust/ql/lib/codeql/rust/dataflow/internal/DataFlowImpl.qll

@@ -241,6 +241,12 @@ module LocalFlow {
       nodeTo.getCfgNode() = s.getPat()
     )
     or
+    // An edge from the right-hand side of a let expression to the left-hand side.
+    exists(LetExprCfgNode e |
+      nodeFrom.getCfgNode() = e.getScrutinee() and
+      nodeTo.getCfgNode() = e.getPat()
+    )
+    or
     exists(IdentPatCfgNode p |
       not p.isRef() and
       nodeFrom.getCfgNode() = p and
@@ -379,6 +385,8 @@ module RustDataFlow implements InputSig<Location> {
   predicate neverSkipInPathGraph(Node node) {
     node.(Node::Node).getCfgNode() = any(LetStmtCfgNode s).getPat()
     or
+    node.(Node::Node).getCfgNode() = any(LetExprCfgNode e).getPat()
+    or
     node.(Node::Node).getCfgNode() = any(AssignmentExprCfgNode a).getLhs()
     or
     exists(MatchExprCfgNode match |
@@ -899,6 +907,12 @@ module VariableCapture {
           v.getPat() = ls.getPat().getPat() and
           ls.getInitializer() = source
         )
+        or
+        exists(LetExprCfgNode le |
+          this = le and
+          v.getPat() = le.getPat().getPat() and
+          le.getScrutinee() = source
+        )
       }
 
       CapturedVariable getVariable() { result = v }

rust/ql/lib/codeql/rust/elements/internal/VariableImpl.qll

@@ -36,6 +36,10 @@ module Impl {
     ClosureBodyScope() { this = any(ClosureExpr ce).getBody() }
   }
 
+  class IfExprScope extends VariableScope, IfExpr { }
+
+  class WhileExprScope extends VariableScope, WhileExpr { }
+
   private Pat getAPatAncestor(Pat p) {
     (p instanceof IdentPat or p instanceof OrPat) and
     exists(Pat p0 | result = p0.getParentPat() |
@@ -152,8 +156,14 @@ module Impl {
     /** Gets the `let` statement that introduces this variable, if any. */
     LetStmt getLetStmt() { this.getPat() = result.getPat() }
 
+    /** Gets the `let` expression that introduces this variable, if any. */
+    LetExpr getLetExpr() { this.getPat() = result.getPat() }
+
     /** Gets the initial value of this variable, if any. */
-    Expr getInitializer() { result = this.getLetStmt().getInitializer() }
+    Expr getInitializer() {
+      result = this.getLetStmt().getInitializer() or
+      result = this.getLetExpr().getScrutinee()
+    }
 
     /** Holds if this variable is captured. */
     predicate isCaptured() { this.getAnAccess().isCapture() }
@@ -193,15 +203,60 @@ module Impl {
     string getName() { result = name_ }
   }
 
+  private AstNode getElseBranch(
+    AstNode elseParentParent, int index, AstNode elseParent, int elseIndex
+  ) {
+    elseParent = getImmediateChild(elseParentParent, index) and
+    result = getImmediateChild(elseParent, elseIndex) and
+    (
+      result = elseParent.(LetStmt).getLetElse()
+      or
+      result = elseParent.(IfExpr).getElse()
+    )
+  }
+
+  private AstNode getLoopBody(LoopingExpr loop) { result = loop.getLoopBody() }
+
+  pragma[nomagic]
+  private Element getImmediateChildAdj(Element e, int preOrd, int index, int postOrd) {
+    result = getImmediateChild(e, index) and
+    preOrd = 0 and
+    postOrd = 0 and
+    not result = getElseBranch(_, _, e, index) and
+    not result = getLoopBody(e)
+    or
+    result = getElseBranch(e, index, _, _) and
+    preOrd = 0 and
+    postOrd = -1
+    or
+    result = getLoopBody(e) and
+    index = 0 and
+    preOrd = 1 and
+    postOrd = 0
+  }
+
+  pragma[nomagic]
+  private Element getImmediateChildAdj(Element e, int index) {
+    result =
+      rank[index + 1](Element res, int i, int preOrd, int postOrd |
+        res = getImmediateChildAdj(e, preOrd, i, postOrd)
+      |
+        res order by preOrd, i, postOrd
+      )
+  }
+
+  private Element getImmediateParentAdj(Element e) { e = getImmediateChildAdj(result, _) }
+
   private AstNode getAnAncestorInVariableScope(AstNode n) {
     (
       n instanceof Pat or
       n instanceof VariableAccessCand or
       n instanceof LetStmt or
+      n instanceof LetExpr or
       n instanceof VariableScope
     ) and
     exists(AstNode n0 |
-      result = getImmediateParent(n0) or
+      result = getImmediateParentAdj(n0) or
       result = n0.(FormatTemplateVariableAccess).getArgument().getParent().getParent()
     |
       n0 = n
@@ -243,31 +298,32 @@ module Impl {
       this instanceof VariableScope or
       this instanceof VariableAccessCand or
       this instanceof LetStmt or
-      getImmediateChild(this, _) instanceof RelevantElement
+      this instanceof LetExpr or
+      getImmediateChildAdj(this, _) instanceof RelevantElement
     }
 
     pragma[nomagic]
-    private RelevantElement getChild(int index) { result = getImmediateChild(this, index) }
+    private RelevantElement getChild(int index) { result = getImmediateChildAdj(this, index) }
 
     pragma[nomagic]
-    private RelevantElement getImmediateChildMin(int index) {
+    private RelevantElement getImmediateChildAdjMin(int index) {
       // A child may have multiple positions for different accessors,
       // so always use the first
       result = this.getChild(index) and
       index = min(int i | result = this.getChild(i) | i)
     }
 
     pragma[nomagic]
-    RelevantElement getImmediateChild(int index) {
+    RelevantElement getImmediateChildAdj(int index) {
       result =
-        rank[index + 1](Element res, int i | res = this.getImmediateChildMin(i) | res order by i)
+        rank[index + 1](Element res, int i | res = this.getImmediateChildAdjMin(i) | res order by i)
     }
 
     pragma[nomagic]
     RelevantElement getImmediateLastChild() {
       exists(int last |
-        result = this.getImmediateChild(last) and
-        not exists(this.getImmediateChild(last + 1))
+        result = this.getImmediateChildAdj(last) and
+        not exists(this.getImmediateChildAdj(last + 1))
       )
     }
   }
@@ -288,13 +344,13 @@ module Impl {
     |
       // first child of a previously numbered node
       result = getPreOrderNumbering(scope, parent) + 1 and
-      n = parent.getImmediateChild(0)
+      n = parent.getImmediateChildAdj(0)
       or
       // non-first child of a previously numbered node
       exists(RelevantElement child, int i |
         result = getLastPreOrderNumbering(scope, child) + 1 and
-        child = parent.getImmediateChild(i) and
-        n = parent.getImmediateChild(i + 1)
+        child = parent.getImmediateChildAdj(i) and
+        n = parent.getImmediateChildAdj(i + 1)
       )
     )
   }
@@ -309,7 +365,7 @@ module Impl {
       result = getPreOrderNumbering(scope, leaf) and
       leaf != scope and
       (
-        not exists(leaf.getImmediateChild(_))
+        not exists(leaf.getImmediateChildAdj(_))
         or
         leaf instanceof VariableScope
       )
@@ -331,7 +387,7 @@ module Impl {
   /**
    * Holds if `v` is named `name` and is declared inside variable scope
    * `scope`. The pre-order numbering of the binding site of `v`, amongst
-   * all nodes nester under `scope`, is `ord`.
+   * all nodes nested under `scope`, is `ord`.
    */
   private predicate variableDeclInScope(Variable v, VariableScope scope, string name, int ord) {
     name = v.getText() and
@@ -354,25 +410,19 @@ module Impl {
           ord = getLastPreOrderNumbering(scope, let) + 1
         )
         or
-        exists(IfExpr ie, LetExpr let |
+        exists(LetExpr let |
           let.getPat() = pat and
-          ie.getCondition() = let and
-          scope = ie.getThen() and
-          ord = getPreOrderNumbering(scope, scope)
+          scope = getEnclosingScope(let) and
+          // for `let` expressions, variables are bound _after_ the statement, i.e.
+          // not in the RHS
+          ord = getLastPreOrderNumbering(scope, let) + 1
         )
         or
         exists(ForExpr fe |
           fe.getPat() = pat and
           scope = fe.getLoopBody() and
           ord = getPreOrderNumbering(scope, scope)
         )
-        or
-        exists(WhileExpr we, LetExpr let |
-          let.getPat() = pat and
-          we.getCondition() = let and
-          scope = we.getLoopBody() and
-          ord = getPreOrderNumbering(scope, scope)
-        )
       )
     )
   }
@@ -612,7 +662,7 @@ module Impl {
     or
     exists(Expr mid |
       assignmentExprDescendant(mid) and
-      getImmediateParent(e) = mid and
+      getImmediateParentAdj(e) = mid and
       not mid instanceof DerefExpr and
       not mid instanceof FieldExpr and
       not mid instanceof IndexExpr

rust/ql/lib/codeql/rust/internal/TypeInference.qll

@@ -328,6 +328,11 @@ private module CertainTypeInference {
         let.getInitializer() = n2
       )
       or
+      exists(LetExpr let |
+        let.getPat() = n1 and
+        let.getScrutinee() = n2
+      )
+      or
       n1 = n2.(ParenExpr).getExpr()
     )
     or
@@ -466,11 +471,6 @@ private predicate typeEquality(AstNode n1, TypePath prefix1, AstNode n2, TypePat
     or
     n1 = n2.(MatchExpr).getAnArm().getExpr()
     or
-    exists(LetExpr let |
-      n1 = let.getScrutinee() and
-      n2 = let.getPat()
-    )
-    or
     exists(MatchExpr me |
       n1 = me.getScrutinee() and
       n2 = me.getAnArm().getPat()