nurfile

use .github/common.nu run-cmd

# Build rust API docs
def "nur docs rs" [
    --open (-o), # open the built docs in the default browser
] {
    mut cmd = [
        "cargo",
        "doc",
        "--no-deps",
        "--lib",
        "--package",
        "cpp-linter",
        "--package",
        "clang-installer",
    ]
    if $open {
        $cmd = $cmd | append "--open"
    }
    run-cmd ...$cmd
}


# Build mkdocs output.
#
# This uses `uv` to drive `mkdocs`.
# This also ensures the cli-gen binding is built because
# the CLI is part of the documentation.
export def "nur docs" [
    --build (-b), # Build the docs without serving them.
    --dirty (-d), # Skip re-building bindings and use the previously built version.
    --open (-o), # Open the built docs in your browser.
] {
    mut sync_args = [--package cli-gen --all-groups]
    let has_cli_gen_installed = (^uv pip show cli-gen) | complete | ($in.exit_code == 0)
    if not $dirty or not $has_cli_gen_installed {
        $sync_args = $sync_args | append [--reinstall-package cli-gen]
    }
    run-cmd uv sync ...$sync_args
    let mkdocs_cmd = if $build { "build" } else { "serve" }
    mut cmd = [
        uv run mkdocs $mkdocs_cmd --config-file docs/mkdocs.yml
    ]
    if $open and not $build {
        $cmd = $cmd | append '--open'
    }
    run-cmd  ...$cmd
    if $open and $build {
        start docs/site/index.html
    }
}


# Run unit tests
#
# To select a profile defined in .config/nextest.toml:
#     nur test --profile ci
#
# Otherwise, the default profile is used.
export def "nur test" [
    --profile (-p): string  = "default", # The nextest profile to use.
    --clean (-c), # Clean before testing
] {
    # run-cmd uv sync --group test
    if $clean {
        run-cmd cargo llvm-cov clean
    }
    let cmd = [
        cargo,
        llvm-cov,
        --no-report,
        nextest,
        --package,
        cpp-linter,
        --package,
        clang-installer,
        --features,
        bin,
        --lib,
        --tests,
        --color,
        always,
        --profile,
        $profile,
    ]
    run-cmd uv run --group test ...$cmd
}

# Generate HTML coverage report
export def "nur test llvm-cov" [
    --open (-o), # Open the built report in your browser.
] {
    mut cmd = [
        cargo
        llvm-cov
        report
        --html
        --ignore-filename-regex
        main
    ]
    if $open {
        $cmd = $cmd | append "--open"
    }
    run-cmd ...$cmd
}

# Generate lcov.info
#
# Useful for codecov uploads and VSCode extensions
# like "Coverage Gutters".
export def "nur test lcov" [] {
    run-cmd ...[
        cargo
        llvm-cov
        report
        --lcov
        --output-path
        lcov.info
        --ignore-filename-regex
        main
    ]
}


# Run clippy and rustfmt
export def "nur lint" [
    --check (-c), # Only check, do not fix
] {
    mut clippy = [cargo clippy --all-features --all-targets]
    if $check {
        $clippy = $clippy | append [-- -D warnings]
    } else {
        $clippy = $clippy | append [--fix --allow-dirty --allow-staged]
    }
    run-cmd ...$clippy
    mut fmt = [cargo fmt]
    if $check {
        $fmt = $fmt | append "--check"
    }
    run-cmd ...$fmt
}

export def "nur pre-commit" [
    --all (-a), # Run pre-commit hooks on all files, not just staged files.
    --upgrade (-U), # Upgrade pre-commit hooks to the latest version.
] {
    if $upgrade {
        run-cmd uv run pre-commit autoupdate
    }
    let args = if $all { ["--all-files"] } else { [] }
    run-cmd uv run pre-commit run ...$args
}