124063/Rod_Kv.mod at master · ModelDBRepository/124063 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
: Rod Photoreceptor Kv channel
:modified 2004-02-05 in obersavation of mixed up of Kx and Kv in Kamiyama's 1996 paper
:based on HH 1952 paper and Koch book
NEURON
{
	SUFFIX Kv

	USEION Kv WRITE iKv VALENCE 1

        RANGE  gKvbar, eKv

}

UNITS
{
	(mA) = (milliamp)
	(mV) = (millivolt)
	(mS) = (millimho)

}

PARAMETER
{
        : potassium delayed rectifier (originally was 2 mS/cm2, -80 mV)
        gKvbar = 10 (mS/cm2) <0,1e9> :was 1
        eKv = -80 (mV) :was -74mV

}

STATE
{
	mKv

}

ASSIGNED
{
	v (mV)

	iKv (mA/cm2)

          : potassium delayed rectifier, K
	infmKv
	taumKv  (ms)

	gKv (mho/cm2)

}

INITIAL
{
	rate(v)
	mKv = infmKv

}


BREAKPOINT
{
	SOLVE states METHOD cnexp
	gKv = (0.001)*gKvbar*mKv*mKv*mKv*mKv
	iKv = gKv*(v - eKv)
}

DERIVATIVE states
{
	rate(v)
	mKv' = (infmKv - mKv)/taumKv

}


UNITSOFF

FUNCTION alphamKv(v(mV)) (/ms)
{
	alphamKv = 0.005*(20-v)/( exp( (20-v)/22) -1 )
 :modified from 10
}

FUNCTION  betamKv (v(mV)) (/ms)
{

	betamKv = 1/16*exp (- v/80 )
}


UNITSON

PROCEDURE rate(v (mV))
{
        LOCAL am, bm


	am = alphamKv(v)
	bm = betamKv(v)
	taumKv = 1/(am + bm)
	infmKv = am*taumKv

}