Day 02: Gift Shop

Author: ACSimon33

2025/apps/day02_gift_shop/.formatter.exs

@@ -0,0 +1,4 @@
+# Used by "mix format"
+[
+  inputs: ["{mix,.formatter}.exs", "{config,lib,test}/**/*.{ex,exs}"]
+]

2025/apps/day02_gift_shop/benchmarks/puzzle_benchmarks.exs

@@ -0,0 +1,24 @@
+defmodule GiftShop.Benchmark do
+  def jobs do
+    input = File.read!(Path.join(__DIR__, "../input/puzzle_input.txt"))
+
+    %{
+      "day02.gift_shop.invalid_id_sum" => fn -> GiftShop.invalid_id_sum(input) end,
+      "day02.gift_shop.extended_invalid_id_sum" => fn -> GiftShop.extended_invalid_id_sum(input) end
+    }
+  end
+end
+
+if System.get_env("AOC_COMBINED_BENCHMARK") do
+  GiftShop.Benchmark.jobs()
+else
+  Benchee.run(
+    GiftShop.Benchmark.jobs(),
+    print: [fast_warning: false],
+    formatters: [{Benchee.Formatters.Console, extended_statistics: true}],
+    warmup: 1,
+    time: 2,
+    memory_time: 2,
+    reduction_time: 2
+  )
+end

2025/apps/day02_gift_shop/input/example_input.txt

@@ -0,0 +1 @@
+11-22,95-115,998-1012,1188511880-1188511890,222220-222224,1698522-1698528,446443-446449,38593856-38593862,565653-565659,824824821-824824827,2121212118-2121212124

2025/apps/day02_gift_shop/input/puzzle_input.txt

@@ -0,0 +1,29 @@
+defmodule GiftShop.CLI do
+  def main(args) do
+    args |> parse_args |> read_file |> run
+  end
+
+  defp parse_args(args) do
+    {options, _, _} =
+      OptionParser.parse(args, switches: [filename: :string], aliases: [f: :filename])
+
+    options[:filename]
+  end
+
+  defp read_file(nil) do
+    IO.puts("Usage: --filename <filename> or -f <filename>")
+    System.halt(1)
+  end
+
+  defp read_file(filename) do
+    File.read!(filename)
+  end
+
+  defp run(input) do
+    IO.puts("Invalid ID sum (2-fold repetition): #{GiftShop.invalid_id_sum(input)}")
+
+    IO.puts(
+      "Invalid ID sum (n-fold repetition, n >= 2): #{GiftShop.extended_invalid_id_sum(input)}"
+    )
+  end
+end

2025/apps/day02_gift_shop/lib/cli.ex

@@ -0,0 +1,59 @@
+defmodule GiftShop do
+  @doc """
+  Sum up all invalid gift IDs that are made of a 2-fold repetition of a number.
+  """
+  def invalid_id_sum(input) do
+    input
+    |> String.split(",")
+    |> Enum.map(&String.split(&1, "-"))
+    |> Enum.map(fn [a, b] ->
+      invalid_ids_in_range(String.to_integer(a), String.to_integer(b), 2)
+    end)
+    |> List.flatten()
+    |> Enum.sum()
+  end
+
+  @doc """
+  Sum up all invalid gift IDs that are made of a n-fold repetition of a number, for n >= 2.
+  """
+  def extended_invalid_id_sum(input) do
+    input
+    |> String.split(",")
+    |> Enum.map(&String.split(&1, "-"))
+    |> Enum.map(fn [a, b] ->
+      Enum.map(2..length(Integer.digits(String.to_integer(b))), fn repeats ->
+        invalid_ids_in_range(String.to_integer(a), String.to_integer(b), repeats)
+      end)
+    end)
+    |> List.flatten()
+    |> Enum.uniq()
+    |> Enum.sum()
+  end
+
+  # Get all invalid IDs in the range [a, b] that are made of `repeats`-fold repetition of a number.
+  defp invalid_ids_in_range(a, b, repeats) do
+    Enum.map(
+      first_number_part(a, repeats, :floor)..first_number_part(b, repeats, :ceil),
+      fn num ->
+        num |> Integer.digits() |> List.duplicate(repeats) |> List.flatten() |> Integer.undigits()
+      end
+    )
+    |> Enum.filter(fn num -> num >= a and num <= b end)
+  end
+
+  # Get the first part of the number when split into `repeats` parts.
+  defp first_number_part(num, repeats, rounding) do
+    digits = Integer.digits(num)
+
+    split_point =
+      case rounding do
+        :floor -> floor(length(digits) / repeats)
+        :ceil -> ceil(length(digits) / repeats)
+      end
+
+    digits
+    |> Enum.split(split_point)
+    |> elem(0)
+    |> Integer.undigits()
+  end
+end

2025/apps/day02_gift_shop/lib/gift_shop.ex

@@ -0,0 +1,51 @@
+defmodule GiftShop.MixProject do
+  use Mix.Project
+
+  def project do
+    [
+      app: :day02_gift_shop,
+      version: "0.1.0",
+      build_path: "../../_build",
+      deps_path: "../../deps",
+      lockfile: "../../mix.lock",
+      elixir: "~> 1.19",
+      start_permanent: Mix.env() == :prod,
+      escript: [main_module: GiftShop.CLI, path: "../../_build/bin/gift_shop"],
+      deps: deps(),
+      aliases: aliases()
+    ]
+  end
+
+  # Run "mix help compile.app" to learn about applications.
+  def application do
+    [
+      extra_applications: [:logger]
+    ]
+  end
+
+  # Run "mix help deps" to learn about dependencies.
+  defp deps do
+    [
+      {:benchee, "~> 1.0"},
+      {:benchee_html, "~> 1.0"},
+      {:junit_formatter, "~> 3.4", only: [:test]}
+    ]
+  end
+
+  defp aliases do
+    [
+      bench: "run #{__DIR__}/benchmarks/puzzle_benchmarks.exs",
+      exec: [&run_escript_with_args/1],
+      solve: ["escript.build", &run_escript/1]
+    ]
+  end
+
+  defp run_escript(_) do
+    Mix.shell().cmd("escript ../../_build/bin/gift_shop -f #{__DIR__}/input/puzzle_input.txt")
+  end
+
+  defp run_escript_with_args(_) do
+    args = System.argv() |> Enum.join(" ")
+    Mix.shell().cmd("escript ../../_build/bin/gift_shop #{args}")
+  end
+end

2025/apps/day02_gift_shop/mix.exs

@@ -0,0 +1,14 @@
+defmodule GiftShopTest do
+  use ExUnit.Case
+  doctest GiftShop
+
+  test "invalid_id_sum" do
+    input = File.read!("input/example_input.txt")
+    assert GiftShop.invalid_id_sum(input) == 1_227_775_554
+  end
+
+  test "extended_invalid_id_sum" do
+    input = File.read!("input/example_input.txt")
+    assert GiftShop.extended_invalid_id_sum(input) == 4_174_379_265
+  end
+end

2025/apps/day02_gift_shop/test/gift_shop_test.exs

@@ -0,0 +1,2 @@
+ExUnit.configure(formatters: [JUnitFormatter, ExUnit.CLIFormatter])
+ExUnit.start()